/****************************************************************************
**
** Copyright (C) 2019 Luxoft Sweden AB
** Copyright (C) 2018 Pelagicore AG
** Copyright (C) 2017 The Qt Company Ltd.
** Contact: http://www.qt.io/licensing/
**
** This file is part of the Qt Quick Controls 2 module of the Qt Toolkit.
**
** $QT_BEGIN_LICENSE:LGPL3$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see http://www.qt.io/terms-conditions. For further
** information use the contact form at http://www.qt.io/contact-us.
**
** GNU Lesser General Public License Usage
** Alternatively, this file may be used under the terms of the GNU Lesser
** General Public License version 3 as published by the Free Software
** Foundation and appearing in the file LICENSE.LGPLv3 included in the
** packaging of this file. Please review the following information to
** ensure the GNU Lesser General Public License version 3 requirements
** will be met: https://www.gnu.org/licenses/lgpl.html.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 2.0 or later as published by the Free
** Software Foundation and appearing in the file LICENSE.GPL included in
** the packaging of this file. Please review the following information to
** ensure the GNU General Public License version 2.0 requirements will be
** met: http://www.gnu.org/licenses/gpl-2.0.html.
**
** $QT_END_LICENSE$
**
****************************************************************************/

import QtQuick
import QtQuick.Templates as T
import QtQuick.Controls
import QtQuick.Controls.impl

import shared.utils
import shared.animations
import shared.Style
import shared.Sizes

T.Switch {
    id: control

    implicitWidth: Math.max(background ? background.implicitWidth : 0,
                            contentItem.implicitWidth + leftPadding + rightPadding)
    implicitHeight: Math.max(background ? background.implicitHeight : 0,
                             Math.max(contentItem.implicitHeight,
                                      indicator ? indicator.implicitHeight : 0) + topPadding + bottomPadding)
    baselineOffset: contentItem.y + contentItem.baselineOffset

    font.weight: Font.Light
    font.pixelSize: Sizes.fontSizeM

    padding: Sizes.dp(8)
    spacing: Sizes.dp(8)

    Cursor {
        onActivated: {
            control.toggle();
        }
        onPressAndHold: {
            control.pressAndHold();
        }
    }

    indicator: PaddedRectangle {
        implicitWidth: Sizes.dp(50)
        implicitHeight: Sizes.dp(30)

        x: text ? (control.mirrored ? control.leftPadding : control.width - width - control.rightPadding) : control.leftPadding + (control.availableWidth - width) / 2
        y: control.topPadding + (control.availableHeight - height) / 2

        radius: Sizes.dp(15)
        leftPadding: 0
        rightPadding: 0
        padding: (height - Sizes.dp(30)) / 2
        color: 'transparent'
        border.width: Sizes.dp(2)
        border.color: control.checked ? Style.accentColor : "#919191"
        opacity: enabled ? Style.opacityHigh : Style.defaultDisabledOpacity

        Rectangle {
            // horizontal margin between the inner ball and the outer capsule
            readonly property real sideMargin: Sizes.dp(4)

            x: Math.max(sideMargin, Math.min(parent.width - width - sideMargin, control.visualPosition * parent.width - (width / 2)))
            y: (parent.height - height) / 2
            width: Sizes.dp(22)
            height: width
            radius: width/2
            color: control.checked ? Style.accentColor : "#919191"

            Behavior on x {
                enabled: !control.down
                DefaultSmoothedAnimation {}
            }
        }
    }

    contentItem: IconLabel {
        leftPadding: control.mirrored ? control.indicator.width + control.spacing : 0
        rightPadding: !control.mirrored ? control.indicator.width + control.spacing : 0

        spacing: control.spacing
        mirrored: control.mirrored
        display: control.display
        alignment: control.display === IconLabel.IconOnly || control.display === IconLabel.TextUnderIcon ? Qt.AlignCenter : Qt.AlignLeft

        icon: control.icon
        text: control.text
        font: control.font
        opacity: enabled ? Style.opacityHigh : Style.defaultDisabledOpacity
        color: Style.contrastColor
    }
}