include(../../../features/utils.pri)

INCLUDEPATH += $${QT_MOBILITY_SOURCE_TREE}/src/sensors
INCLUDEPATH += $${QT_MOBILITY_SOURCE_TREE}/src/sensors/gestures

INCLUDEPATH += ../../../src/global

TEMPLATE = lib
CONFIG += plugin
TARGET  = $$mobilityPluginTarget(declarative_sensors)
TARGETPATH = QtMobility/sensors
PLUGIN_TYPE = declarative
include(../../../common.pri)

QT += declarative

SOURCES += sensors.cpp \
qmlsensorgesture.cpp
HEADERS += qmlsensorgesture.h

CONFIG += mobility
MOBILITY += sensors

target.path = $$[QT_INSTALL_IMPORTS]/$$TARGETPATH

qmldir.files += $$PWD/qmldir
qmldir.path +=  $$[QT_INSTALL_IMPORTS]/$$TARGETPATH

INSTALLS += qmldir

symbian {
    # In Symbian, a library should enjoy _largest_ possible capability set.
    TARGET.CAPABILITY = ALL -TCB
    # Allow writable DLL data
    TARGET.EPOCALLOWDLLDATA = 1
    # Target UID, makes every Symbian app unique
    TARGET.UID3 = $$mobilityUID(0x20021324)
    # Specifies what files shall be deployed: the plugin itself and the qmldir file.
    importFiles.sources = $$DESTDIR/declarative_sensors$${QT_LIBINFIX}.dll qmldir 
    importFiles.path = $$QT_IMPORTS_BASE_DIR/$$TARGETPATH
    DEPLOYMENT = importFiles
 }