QT += network

TARGET = GeoServiceDemo
TEMPLATE = app

INCLUDEPATH += ../../../../src/location \
               ../../../../src/location/maps

SOURCES += main.cpp\
        routepresenter.cpp \
        placepresenter.cpp \
        tabbedwindow.cpp \
        routetab.cpp \
        geocodingtab.cpp \
        revgeocodingtab.cpp \
        directionstab.cpp \
        servicestab.cpp 

HEADERS  += routepresenter.h \
        placepresenter.h \
        tabbedwindow.h \
        routetab.h \
        geocodingtab.h \
        revgeocodingtab.h \
        directionstab.h \
        servicestab.h

RESOURCES += geoservicedemo.qrc

include(../../../../examples/mobility_examples.pri)

CONFIG += mobility
MOBILITY = location 
equals(QT_MAJOR_VERSION, 4):lessThan(QT_MINOR_VERSION, 7){
    MOBILITY += bearer
    INCLUDEPATH += ../../../../src/bearer
} else {
    # use Bearer Management classes in QtNetwork module
}

symbian: {
    TARGET.CAPABILITY = Location \
                        NetworkServices \
                        ReadUserData \
                        WriteUserData \
                        ReadDeviceData \
                        WriteDeviceData
}

maemo*:CONFIG += manual_test