Add initial (untested) OBDII examples

Author: sandeepmistry

examples/OBDII/EngineRPM/EngineRPM.ino

@@ -0,0 +1,48 @@
+#include <CAN.h>
+
+// Most cars support 11-bit adddress, others (like Honda),
+// require 29-bit (extended) addressing, set the next line
+// to true to use extended addressing
+const bool useStandardAddressing = true;
+
+void setup() {
+  Serial.begin(9600);
+
+  Serial.println("CAN OBD-II supported pids");
+
+  // start the CAN bus at 500 kbps
+  if (!CAN.begin(500E3)) {
+    Serial.println("Starting CAN failed!");
+    while (1);
+  }
+
+  if (useStandardAddressing) {
+    CAN.filter(0x7e8);
+  } else {
+    CAN.filterExtended(0x18daf110);
+  }
+}
+
+void loop() {
+  if (useStandardAddressing) {
+    CAN.beginPacket(0x7df, 8);
+  } else {
+    CAN.beginExtendedPacket(0x18db33f1, 8);
+  }
+  CAN.write(0x02); // number of additional bytes
+  CAN.write(0x01); // show current data
+  CAN.write(0x0c); // engine RPM
+  CAN.endPacket();
+
+  // wait for response
+  while (CAN.parsePacket() == 0 ||
+         CAN.read() != 0x41 ||                       // correct mode
+         CAN.read() != 0x0c);                        // correct PID
+
+  float rpm = ((CAN.read() * 256.0) + CAN.read()) / 4.0;
+
+  Serial.print("Engine RPM = ");
+  Serial.println(rpm);
+
+  delay(1000);
+}

examples/OBDII/SupportedPIDs/SupportedPIDs.ino

@@ -0,0 +1,70 @@
+#include <CAN.h>
+
+// Most cars support 11-bit adddress, others (like Honda),
+// require 29-bit (extended) addressing, set the next line
+// to true to use extended addressing
+const bool useStandardAddressing = true;
+
+void setup() {
+  Serial.begin(9600);
+
+  Serial.println("CAN OBD-II supported pids");
+
+  // start the CAN bus at 500 kbps
+  if (!CAN.begin(500E3)) {
+    Serial.println("Starting CAN failed!");
+    while (1);
+  }
+
+  if (useStandardAddressing) {
+    CAN.filter(0x7e8);
+  } else {
+    CAN.filterExtended(0x18daf110);
+  }
+}
+
+void loop() {
+  for (int pid = 0x00; pid < 0xe0; pid += 0x20) {
+    if (useStandardAddressing) {
+      CAN.beginPacket(0x7df, 8);
+    } else {
+      CAN.beginExtendedPacket(0x18db33f1, 8);
+    }
+    CAN.write(0x02); // number of additional bytes
+    CAN.write(0x01); // show current data
+    CAN.write(pid); // PID
+    CAN.endPacket();
+
+    // wait for response
+    while (CAN.parsePacket() == 0 ||
+           CAN.read() < 6 ||         // correct length
+           CAN.read() != 0x41 ||     // correct mode
+           CAN.read() != pid);       // correct PID
+
+    unsigned long pidsSupported = 0;
+
+    for (int i = 0; i < 4; i++) {
+      pidsSupported <<= 8;
+      pidsSupported |= CAN.read();
+    }
+
+    for (unsigned int i = 31; i > 0; i--) {
+      if (pidsSupported & (1UL << i)) {
+        int pidSupported = pid + (32 - i);
+
+        Serial.print("0x");
+        if (pidSupported < 16) {
+          Serial.print("0");
+        }
+        Serial.println(pidSupported, HEX);
+      }
+    }
+
+    if ((pidsSupported & 0x00000001) == 0x00000000) {
+      // next round not supported, all done
+      break;
+    }
+  }
+
+  while (1); // all done
+}

examples/OBDII/VINReader/VINReader.ino

@@ -0,0 +1,72 @@
+#include <CAN.h>
+
+// Most cars support 11-bit adddress, others (like Honda),
+// require 29-bit (extended) addressing, set the next line
+// to true to use extended addressing
+const bool useStandardAddressing = true;
+
+void setup() {
+  Serial.begin(9600);
+
+  Serial.println("CAN OBD-II VIN reader");
+
+  // start the CAN bus at 500 kbps
+  if (!CAN.begin(500E3)) {
+    Serial.println("Starting CAN failed!");
+    while (1);
+  }
+
+  if (useStandardAddressing) {
+    CAN.filter(0x7e8);
+  } else {
+    CAN.filterExtended(0x18daf110);
+  }
+}
+
+void loop() {
+  // send the request for the first chunk
+  if (useStandardAddressing) {
+    CAN.beginPacket(0x7df, 8);
+  } else {
+    CAN.beginExtendedPacket(0x18db33f1, 8);
+  }
+  CAN.write(0x02); // Number of additional bytes
+  CAN.write(0x09); // Request vehicle information
+  CAN.write(0x02); // Vehicle Identification Number (VIN)
+  CAN.endPacket();
+
+  // wait for response
+  while (CAN.parsePacket() == 0 ||
+         CAN.read() != 0x10 || CAN.read() != 0x14 || // correct length
+         CAN.read() != 0x49 ||                       // correct mode
+         CAN.read() != 0x02 ||                       // correct PID
+         CAN.read() != 0x01);
+
+  // print out
+  while (CAN.available()) {
+    Serial.write((char)CAN.read());
+  }
+
+  // send the request for the remaining bytes
+  if (useStandardAddressing) {
+    CAN.beginPacket(0x7e0, 8);
+  } else {
+    CAN.beginExtendedPacket(0x18db10f1, 8); // TODO - verify this
+  }
+  CAN.write(0x30);
+  CAN.endPacket();
+
+  // read in remaining bytes
+  for (int i = 0; i < 2; i++) {
+    // wait for response
+    while (CAN.parsePacket() == 0 ||                 // wait for response
+           CAN.read() != 0x21);
+
+    // print out
+    while (CAN.available()) {
+      Serial.write((char)CAN.read());
+    }
+  }
+
+  while (1); // all done
+}