New plugin.

Author: coderifous

doc/textobj-word-column.txt

@@ -0,0 +1,78 @@
+*textobj-word-column.txt*  Adds text-objects for word-based columns.
+
+===============================================================================
+CONTENTS                                         *textobj-word-column-contents*
+
+    1. Intro...............................|textobj-word-column-intro|
+    2. Commands............................|textobj-word-column-mappings|
+    3. Mappings............................|textobj-word-column-examples|
+    4. Contributing........................|textobj-word-column-contributing|
+    5. Credits.............................|textobj-word-column-credits|
+    6. Changelog...........................|textobj-word-column-changelog|
+
+===============================================================================
+INTRO                                               *textobj-word-column-intro*
+
+The word-based column |text-object| makes operating on columns of code
+conceptually simpler and reduces keystrokes.
+
+The common task of deleting, changing, or adding to a vertical column of code
+can be achieved using |visual-blocks|, however the first step is to establish
+the visual block itself.  This typically involves moving the cursor to the
+start of the block, and then using vim motions to move the cursor to the end of
+the block, and finally doing the appropriate operation.
+
+With a text object for columns, establishing the visual block is much easer,
+and even unecessary for certain operations.
+
+===============================================================================
+WORD-BASED COLUMN                                *textobj-word-column-mappings*
+
+                                                   *ac* *cac* *dac* *vac* *yac*
+ac               "a column", a column based on "a word" |aw|.
+
+                                                   *ic* *cic* *dic* *vic* *yic*
+ic               "inner column", a column based on the "inner word" |iw|.
+
+                                                   *aC* *caC* *daC* *vaC* *yaC*
+aC               "a COLUMN", a column based on "a WORD" |aW|.
+
+                                                   *iC* *ciC* *diC* *viC* *yiC*
+iC               "inner COLUMN", a column based on "inner WORD" |iW|.
+
+===============================================================================
+USAGE EXAMPLES                                   *textobj-word-column-examples*
+
+vic                      Visually select a column.
+
+cic                      Change a column.
+
+dac                      Delete a column.
+
+vicI                     Prepend new text to a column.
+
+vicA                     Append new text to a column.
+
+viC                      Visually select a WORD based colunn.
+
+===============================================================================
+CONTRIBUTING                                 *textobj-word-column-contributing*
+
+The goal of this plugin is to be able to operate on conceptual columns of code
+without the hassle of manually demarcating their boundaries.  If you find a
+case where the selected column wasn't what you expected AND there's a logical
+way to fix or add a boundary condition for that case, then submit an issue via
+github.  If you'd like to add the fix yourself, please fork the plugin, make
+your changes in a branch, and then submit a pull request for that branch.
+
+===============================================================================
+CREDITS                                           *textobj-word-column-credits*
+
+Developed by Jim Garvin <http://github.com/coderifous>.
+
+Git repository: https://github.com/coderifous/textobj-word-column.vim
+
+===============================================================================
+CHANGELOG                                       *textobj-word-column-changelog*
+
+First Public Release: 2012/06/18

plugin/textobj/word-column.vim

@@ -0,0 +1,41 @@
+if (exists("g:loaded_textobj_word_column"))
+  finish
+endif
+
+function! TextObjWordBasedColumn()
+  let startcol    = col("'<")
+  let stopcol     = col("'>")
+  let linenum     = line(".")
+  let indentlevel = s:indent_level(".")
+  let startline   = s:find_boundary_row(linenum, indentlevel, -1)
+  let stopline    = s:find_boundary_row(linenum, indentlevel, 1)
+  exec "silent normal!" startline . "gg" . startcol . "|" stopline . "gg" . stopcol . "|"
+endfunction
+
+function! s:find_boundary_row(linenum, indentlevel, step)
+  let sameindent = s:indent_level(a:linenum + a:step) == a:indentlevel
+  let nonblank   = getline(a:linenum + a:step) =~ "[^ \t]"
+  if sameindent && nonblank
+    return s:find_boundary_row(a:linenum + a:step, a:indentlevel, a:step)
+  else
+    return a:linenum
+  endif
+endfunction
+
+function! s:indent_level(linenum)
+  let line = getline(a:linenum)
+  return match(line, "[^ \t]")
+endfunction
+
+if (!exists("g:skip_default_textobj_word_column_mappings"))
+  vnoremap <silent> ac <Esc>vaw:call TextObjWordBasedColumn()<cr>
+  vnoremap <silent> aC <Esc>vaW:call TextObjWordBasedColumn()<cr>
+  vnoremap <silent> ic <Esc>viw:call TextObjWordBasedColumn()<cr>
+  vnoremap <silent> iC <Esc>viW:call TextObjWordBasedColumn()<cr>
+  onoremap <silent> ac :normal vac<cr>
+  onoremap <silent> aC :normal vaC<cr>
+  onoremap <silent> ic :normal vic<cr>
+  onoremap <silent> iC :normal viC<cr>
+endif
+
+let g:loaded_textobj_word_column = 1