Make puppet module cross-platform

Author: elasticdog

provision/modules/puppet/manifests/init.pp

@@ -4,6 +4,11 @@
 #
 # === Parameters
 #
+# [*ensure*]
+#   What state the package should be in. Defaults to +latest+. Valid values are
+#   +present+ (also called +installed+), +absent+, +purged+, +held+, +latest+,
+#   or a specific version number.
+#
 # === Actions
 #
 # - Install Puppet client package
@@ -15,16 +20,30 @@
 #
 #   class { 'puppet': }
 #
-class puppet {
+#   class { 'puppet':
+#     ensure => '2.6.8-0.5.el5',
+#   }
+#
+class puppet(
+  $ensure = $puppet::params::client_ensure
+) inherits puppet::params {
 
   package { 'puppet':
-    ensure => latest,
+    ensure => $ensure,
+  }
+
+  # required to start client agent on ubuntu
+  exec { 'start_puppet':
+    command => '/bin/sed -i /etc/default/puppet -e "s/START=no/START=yes/"',
+    onlyif  => '/usr/bin/test -f /etc/default/puppet',
+    require => Package[ 'puppet' ],
+    before  => Service[ 'puppet' ],
   }
 
   service { 'puppet':
     enable  => true,
     ensure  => running,
-    require => Package['puppet'],
+    require => Package[ 'puppet' ],
   }
 
 }

provision/modules/puppet/manifests/params.pp

@@ -0,0 +1,32 @@
+# == Class: puppet::params
+#
+# This class manages the Puppet parameters. 
+#
+# === Parameters
+#
+# === Actions
+#
+# === Requires
+#
+# === Sample Usage
+#
+# This class file is not called directly.
+#
+class puppet::params {
+
+  $client_ensure = 'latest'
+  $server_ensure = 'latest'
+
+  case $::operatingsystem {
+    'centos', 'fedora', 'redhat', 'scientific': {
+      $server_package_name = 'puppet-server'
+    }
+    'debian', 'ubuntu': {
+      $server_package_name = 'puppetmaster'
+    }
+    default: {
+      fail("Module 'puppet' is not currently supported by Puppet Sandbox on ${::operatingsystem}")
+    }
+  }
+
+}

provision/modules/puppet/manifests/server.pp

@@ -4,23 +4,47 @@
 #
 # === Parameters
 #
+# [*ensure*]
+#   What state the package should be in. Defaults to +latest+. Valid values are
+#   +present+ (also called +installed+), +absent+, +purged+, +held+, +latest+,
+#   or a specific version number.
+#
+# [*package_name*]
+#   The name of the package on the relevant distribution. Default is set by
+#   Class['puppet::params'].
+#
 # === Actions
 #
 # - Install Puppet server package
-# - Ensure puppet-master daemon is running
-# - Configure Puppet to use nodes.pp and modules from /vagrant directory
 # - Configure Puppet to autosign puppet client certificate requests
+# - Configure Puppet to use nodes.pp and modules from /vagrant directory
+# - Ensure puppet-master daemon is running
 #
 # === Requires
 #
 # === Sample Usage
 #
 #   class { 'puppet::server': }
 #
-class puppet::server {
+#   class { 'puppet::server':
+#     ensure => '2.6.8-0.5.el5',
+#   }
+#
+class puppet::server(
+  $ensure       = $puppet::params::server_ensure,
+  $package_name = $puppet::params::server_package_name
+) inherits puppet::params {
 
-  package { 'puppet-server':
-    ensure => latest,
+  # required to prevent syslog error on ubuntu
+  # https://bugs.launchpad.net/ubuntu/+source/puppet/+bug/564861
+  file { [ '/etc/puppet', '/etc/puppet/files' ]:
+    ensure => directory,
+    before => Package[ 'puppetmaster' ],
+  }
+
+  package { 'puppetmaster':
+    ensure => $ensure,
+    name   => $package_name,
   }
 
   file { 'puppet.conf':
@@ -29,8 +53,8 @@
     group   => 'puppet',
     mode    => '0644',
     source  => 'puppet:///modules/puppet/puppet.conf',
-    require => Package[ 'puppet-server' ],
-    notify  => Service[ 'puppet-server' ],
+    require => Package[ 'puppetmaster' ],
+    notify  => Service[ 'puppetmaster' ],
   }
 
   file { 'site.pp':
@@ -39,35 +63,34 @@
     group   => 'puppet',
     mode    => '0644',
     source  => 'puppet:///modules/puppet/site.pp',
-    require => Package[ 'puppet-server' ],
+    require => Package[ 'puppetmaster' ],
+  }
+
+  file { 'autosign.conf':
+    path    => '/etc/puppet/autosign.conf',
+    owner   => 'puppet',
+    group   => 'puppet',
+    mode    => '0644',
+    content => '*',
+    require => Package[ 'puppetmaster' ],
   }
 
   file { '/etc/puppet/manifests/nodes.pp':
     ensure  => link,
     target  => '/vagrant/nodes.pp',
+    require => Package[ 'puppetmaster' ],
   }
 
   # initialize a template file then ignore
   file { '/vagrant/nodes.pp':
     ensure  => present,
     replace => false,
     source  => 'puppet:///modules/puppet/nodes.pp',
-    require => Package[ 'puppet-server' ],
-  }
-
-  file { 'autosign.conf':
-    path    => '/etc/puppet/autosign.conf',
-    owner   => 'puppet',
-    group   => 'puppet',
-    mode    => '0644',
-    content => '*',
-    require => Package[ 'puppet-server' ],
   }
 
-  service { 'puppet-server':
+  service { 'puppetmaster':
     enable => true,
     ensure => running,
-    name   => 'puppetmaster',
   }
 
 }