Have you got a function to convert time/date from free form

[jkour]

Hi,
I was looking at the datetime util but couldn't find any methods to do what I need.

Is there a method to convert natural language date/time to TDateTime?
For example, for the input "3hrs and 5mins" to produce the relevant TDateTime?
Thanks

[Bi0T1N]

No, you need to extract the values by yourself and then use appropriate functions to create TDateTime.

One example using RegularExpressions:

program NaturalLanguageToTDateTime;

{$APPTYPE CONSOLE}

uses
  System.SysUtils, System.RegularExpressions;

var
  Pattern: String = '(\d{1,2})\s?(\w+)';
  MatchCollection: TMatchCollection;
  Match: TMatch;
  IntValue: Integer;
  TimeValue: String;
  Time: TDateTime;
  HrsValue, MinsValue: Integer;
  ResultString: String;

begin
  try
    MatchCollection := TRegEx.Matches('3hrs and 5mins', Pattern, [roIgnoreCase]);
    for Match in MatchCollection do
    begin
      writeln(Format('Full Match: %s', [Match.Value]));
      IntValue := TGroup(Match.Groups.Item[1]).Value.ToInteger;
      TimeValue := TGroup(Match.Groups.Item[2]).Value;
      writeln(Format('IntValue: %d', [IntValue]));
      writeln(Format('TimeValue: %s', [TimeValue]));

      if TimeValue.StartsWith('hr') then
        HrsValue := IntValue;
      if TimeValue.StartsWith('min') then
        MinsValue := IntValue;

      writeln(sLineBreak);
    end;

    Time := EncodeTime(HrsValue, MinsValue, 0, 0);

    DateTimeToString(ResultString, 'hh:nn', Time);
    writeln(Format('Resulting TDateTime as String: %s', [ResultString]));

    readln;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

You can also use

procedure SetHour(var D: TDateTime; const Hour: Word);
procedure SetMinute(var D: TDateTime; const Minute: Word);

instead of EncodeTime.