WL#16156: Add version info resources on Windows

Change-id: Ied7be424376ccd5019992ab11a3516b2beb73bcd

Author: rsomla1

CMakeLists.txt

@@ -81,6 +81,7 @@ include(platform)
 include(dependency)      # find_dependency()
 include(config_options)  # add_config_option()
 include(libutils)        # merge_libraries()
+include(version_info)    # set_version_info()
 
 #
 # Detect if we are configured as stand-alone project, or sub-project.
@@ -352,7 +353,6 @@ if(WITH_JDBC)
     PUBLIC "${PROJECT_BINARY_DIR}/include/jdbc"
     PUBLIC "${PROJECT_BINARY_DIR}/include/jdbc/cppconn"
     PUBLIC "${PROJECT_SOURCE_DIR}/include"
-
   )
 
 endif()
@@ -405,6 +405,11 @@ add_subdirectory(devapi)
 # Generate the main connector library.
 
 merge_libraries(connector xapi devapi)
+add_version_info(connector
+  "MySQL Connector/C++ XDevAPI library."
+  "Implements MySQL Connector/C++ XDevAPI."
+)
+
 target_include_directories(connector PUBLIC
   "${PROJECT_SOURCE_DIR}/include"
   # Note: This is needed when using connector directly from the build tree to
@@ -445,16 +450,16 @@ if(0)
 #  Add command to show rpath information
 #
 
-if(APPLE)
-  set(list_rpath_cmd otool -l $<TARGET_FILE:libconcpp> "|" grep RPATH -A2)
-elseif(NOT WIN32)
-  set(list_rpath_cmd objdump -x $<TARGET_FILE:libconcpp> "|" grep RPATH -A2)
-endif()
+  if(APPLE)
+    set(list_rpath_cmd otool -l $<TARGET_FILE:libconcpp> "|" grep RPATH -A2)
+  elseif(NOT WIN32)
+    set(list_rpath_cmd objdump -x $<TARGET_FILE:libconcpp> "|" grep RPATH -A2)
+  endif()
 
-add_custom_command(TARGET connector POST_BUILD
-  COMMAND ${list_rpath_cmd}
-  COMMENT "RPATH setting for: $<TARGET_FILE_NAME:mysqlcppconn>"
-)
+  add_custom_command(TARGET connector POST_BUILD
+    COMMAND ${list_rpath_cmd}
+    COMMENT "RPATH setting for: $<TARGET_FILE_NAME:mysqlcppconn>"
+  )
 endif()
 
 
@@ -500,7 +505,6 @@ endif()
 # Note: Locations and names are configured in install_layout.cmake
 #
 
-
 set_property(TARGET connector PROPERTY OUTPUT_NAME ${LIB_NAME})
 message("Connector library name: ${LIB_NAME}")
 

cmake/version_info.cmake

@@ -0,0 +1,94 @@
+
+
+add_config_option(SHOW_VERSION_INFO BOOL ADVANCED DEFAULT ${MAINTAINER_MODE}
+  "Show version information for targets built on Windows"
+)
+
+get_filename_component(VERSION_INFO_HOME "${CMAKE_CURRENT_LIST_DIR}/version_info" ABSOLUTE CACHE)
+
+
+#
+# Add Windows version info resources to the library/executable file produced
+# by target TGT.
+#
+# This is ignored on non-Windows platforms. The second argument is a string
+# to use as `FileDescription` attribute. If another argument is given, it
+# is used for `Comments` attribute.
+#
+# Note: Version information is taken from version.cmake file included by
+# gen_version_info.cmake script that generates resource definitions.
+#
+#
+
+function(add_version_info TGT DESCR)
+
+  if(NOT WIN32)
+    return()
+  endif()
+
+  get_target_property(TYPE ${TGT} TYPE)
+
+  # Currently setting version resources for static libraries does not work.
+  # Possibly because of the machinery we use to merge static library from
+  # several smaller ones. For now we can live without version info in static
+  # libraries.
+
+  if(TYPE STREQUAL "STATIC_LIBRARY")
+    return()
+  endif()
+
+  set(out "${CMAKE_CURRENT_BINARY_DIR}/${TGT}_version_info.rc")
+
+  # Command to generate .rc file with version information. This is done
+  # by the gen_version_info.cmake script which uses version_info.rc.in template.
+
+  add_custom_command(OUTPUT "${out}"
+    COMMAND ${CMAKE_COMMAND}
+      -D "RC=${out}"
+      -D "OUTPUT=$<TARGET_FILE:${TGT}>"
+      -D "TYPE=${TYPE}"
+      -D "DESCRIPTION=${DESCR}"
+      -D "COMMENTS=${ARGN}"
+      -D "VERSION=${CMAKE_SOURCE_DIR}/version.cmake"
+      -D "CONFIG=$<CONFIG>"
+      -P "${VERSION_INFO_HOME}/gen_version_info.cmake"
+  )
+
+  # Add the generated .rc file to the sources of the target.
+
+  target_sources(${TGT} PRIVATE "${out}")
+
+  if(SHOW_VERSION_INFO)
+    show_version_info(${TGT})
+  endif()
+
+  #add_custom_command(TARGET ${TGT} POST_BUILD
+  #  COMMAND ${CMAKE_COMMAND} -E rm -rf "${out}"
+  #)
+
+  message(STATUS "generated version info for target ${TGT} (${TYPE}): ${out}")
+
+endfunction()
+
+#
+# Arrange for a library/executable target TGT to show the version information
+# resources once its file is generated.
+#
+# This command is ignored on non-Windows platforms or if the target does not
+# exist.
+#
+
+function(show_version_info TGT)
+
+  if(NOT WIN32 OR NOT TARGET ${TGT})
+    return()
+  endif()
+
+  add_custom_command(TARGET ${TGT} POST_BUILD
+  COMMAND ${CMAKE_COMMAND}
+    -D FILE=$<TARGET_FILE:${TGT}>
+    -P "${VERSION_INFO_HOME}/show_version_info.cmake"
+  )
+
+endfunction()
+

cmake/version_info/gen_version_info.cmake

@@ -0,0 +1,31 @@
+message("Re-generating version info resource defintions: ${RC}")
+message("For output file: ${OUTPUT}")
+message("Of type: ${TYPE}")
+message("Build configuration: ${CONFIG}")
+
+include("${VERSION}")
+
+
+set(PATH "${OUTPUT}")
+get_filename_component(BASE "${OUTPUT}" NAME)
+get_filename_component(BASE_WE "${OUTPUT}" NAME_WE)
+
+string(REPLACE "." "," CONCPP_VERSION_RAW "${CONCPP_VERSION}")
+
+if("STATIC_LIBRARY" STREQUAL TYPE)
+  set(FILETYPE "VFT_STATIC_LIB")
+elseif(TYPE MATCHES "_LIBRARY")
+  set(FILETYPE "VFT_DLL")
+elseif("EXECUTABLE" STREQUAL TYPE)
+  set(FILETYPE "VFT_APP")
+else()
+  set(FILETYPE 0)
+endif()
+
+set(FILEFLAGS 0)
+if(CONFIG MATCHES "[Dd][Ee][Bb][Uu][Gg]")
+  set(FILEFLAGS "VS_FF_DEBUG")
+endif()
+
+
+configure_file("${CMAKE_CURRENT_LIST_DIR}/version_info.rc.in" "${RC}" @ONLY)

cmake/version_info/show_version_info.cmake

@@ -0,0 +1,5 @@
+find_program(PWS powershell)
+if(PWS)
+  message("Version information for: ${FILE}")
+  execute_process(COMMAND ${PWS} -command "ls ${FILE} | % VersionInfo | fl *")
+endif()

cmake/version_info/version_info.rc.in

@@ -0,0 +1,33 @@
+// Version info resources for @BASE@
+// Note: This is a generated file -- see cmake/version_info.cmake in the source tree.
+
+#include <windows.h>
+#define VER_PRIVATEBUILD 0x0L
+#define VER_PRERELEASE 0x0L
+
+
+VS_VERSION_INFO VERSIONINFO
+  FILEVERSION    @CONCPP_VERSION_RAW@,0
+  PRODUCTVERSION @CONCPP_VERSION_RAW@,0
+  FILEFLAGSMASK  VS_FFI_FILEFLAGSMASK
+  FILEFLAGS      @FILEFLAGS@
+  FILEOS         VOS__WINDOWS32
+  FILETYPE       @FILETYPE@
+BEGIN
+    BLOCK "StringFileInfo"
+    BEGIN
+        BLOCK "040904b0"
+        BEGIN
+            VALUE "CompanyName", "Oracle Corporation\0"
+            VALUE "ProductName", "MySQL Connector/C++\0"
+            VALUE "ProductVersion", "@[email protected]\0"
+            VALUE "FileVersion", "@[email protected]\0"
+            VALUE "LegalCopyright", "Copyright (c) 1995, @COPYRIGHT_YEAR@, Oracle and/or its affiliates.\0"
+            VALUE "LegalTrademarks", "Oracle(R), Java, MySQL, and NetSuite are registered trademarks of Oracle and/or its affiliates.\0"
+            VALUE "OriginalFileName", "@BASE@\0"
+            VALUE "InternalName", "@BASE_WE@\0"
+            VALUE "FileDescription", "@DESCRIPTION@\0"
+            VALUE "Comments", "@COMMENTS@\0"
+        END
+    END
+END

jdbc/CMakeLists.txt

@@ -256,6 +256,12 @@ set(INFO_PREFIX "jdbc-")
 
 merge_libraries(connector-jdbc jdbc)
 
+add_version_info(connector-jdbc
+  "MySQL Connector/C++ legacy (JDBC) library."
+  "Implements MySQL Connector/C++ legacy JDBC API."
+)
+
+
 
 # Note: When connector links statically to the client library, targets using
 # the connector must be able to find dependencies of the client library, such

jdbc/test/CMakeLists.txt

@@ -66,6 +66,11 @@ ENDIF(CMAKE_COMPILER_IS_GNUCC AND MYSQLCPPCONN_GCOV_ENABLE)
 
 ADD_EXECUTABLE(static_test static_test.cpp)
 
+add_version_info(static_test
+  "MySQL Connector/C++ unit test."
+  "Tests MySQL Connector/C++ functionality."
+)
+
 SET_TARGET_PROPERTIES(static_test PROPERTIES
   LINK_FLAGS "${MYSQLCPPCONN_LINK_FLAGS_ENV} ${MYSQL_LINK_FLAGS}"
   COMPILE_FLAGS "${MYSQLCPPCONN_COMPILE_FLAGS_ENV}"
@@ -80,6 +85,11 @@ TARGET_LINK_LIBRARIES(static_test ${MY_TARGET_LINK_LIBRARIES} ${MY_GCOV_LINK_LIB
 LINK_DIRECTORIES(${GLIB_DIR}/lib)
 ADD_EXECUTABLE(driver_test driver_test.cpp)
 
+add_version_info(driver_test
+  "MySQL Connector/C++ unit test."
+  "Tests MySQL Connecto/C++ functionality."
+)
+
 SET_TARGET_PROPERTIES(driver_test PROPERTIES
   LINK_FLAGS "${MYSQLCPPCONN_LINK_FLAGS_ENV} ${MYSQL_LINK_FLAGS}"
   COMPILE_FLAGS "${MYSQLCPPCONN_COMPILE_FLAGS_ENV}"
@@ -95,11 +105,18 @@ function(add_unit_test NAME)
 
   if (ARGN)
     list(GET ARGN 0 TGT_NAME)
+    set(description "MySQL Connector/C++ usage example.")
+    set(comments "Runs demo code.")
   else()
     set(TGT_NAME test_${NAME})
+    set(description "MySQL Connector/C++ unit test.")
+    set(comments "Tests MySQL Connector/C++ functionality.")
   endif()
 
   ADD_EXECUTABLE(${TGT_NAME} ${test_${NAME}_sources})
+
+  add_version_info(${TGT_NAME} "${description}" "${comments}")
+
   SET_TARGET_PROPERTIES(${TGT_NAME} PROPERTIES
     OUTPUT_NAME "${NAME}"
     LINK_FLAGS "${MYSQLCPPCONN_LINK_FLAGS_ENV} ${MYSQL_LINK_FLAGS}"

testing/tests.cmake

@@ -53,6 +53,11 @@ IF (WITH_TESTS)
   # Unit tests declared with ADD_NG_TEST() (see cdk/cmake/testing.cmake)
   ADD_TEST_TARGET()
 
+  add_version_info(run_unit_tests
+    "MySQL Connector/C++ unit tests."
+    "Tests MySQL Connector/C++ functionality."
+  )
+
   # Install these as part of `Tests` component.
 
   install(

version.cmake

@@ -26,6 +26,10 @@
 # along with this program; if not, write to the Free Software Foundation, Inc.,
 # 51 Franklin St, Fifth Floor, Boston, MA 02110-1301  USA
 
+# Note: To be used in copyright notes of generated files
+
+set(COPYRIGHT_YEAR "2024" CACHE INTERNAL "version info")
+
 #
 # Connector/C++ version
 #