批处理FTP密码更改程序

最新推荐文章于 2026-06-17 17:50:55 发布

转载最新推荐文章于 2026-06-17 17:50:55 发布 · 3.1k 阅读

标签

#服务器 #数据备份

深入windows 专栏收录该内容

16 篇文章

订阅专栏

本文介绍了一个用于修改公司内网FTP个人登录密码的批处理脚本。该脚本通过命令行方式实现，能够自动完成从输入用户名、原密码及新密码到修改密码的整个过程，并反馈操作结果。

@echo off
Color 0a
mode con lines=20 cols=49
title FTP个人密码更改V1.0 Code By jl_li

:: ****************************
:: * 此段为程序运行显示的信息 *
:: ****************************
echo.
echo. 说明
echo.
echo 本程序仅适用于更改公司内网数据备份FTP个人登录密码
echo.
echo　_______________ 版权没有☆翻版随意 ______________
echo.

:START
:: *********************************************
:: * 此段为设置服务器IP地址，并输出到FTP文件中 *
:: * 如果想让用户自行输入IP更改为如下代码即可 *
:: *    set ip=                                *
:: *    set/p ip=请输入服务器IP地址:           *
:: *    echo open %ip% >ftp                    *
:: *********************************************
echo open 192.168.148.18 >ftp

:: ************************************************
:: * 以下为输入用户名和原密码以及新密码,并将密码 *
:: * 和更改密码命令以及退出FTP命令发送到FTP文件中 *
:: ************************************************
set username=
set/p username=请输入用户名:
echo %username% >>ftp
set oldpassword=
set/p oldpassword=请输入原密码:
echo %oldpassword% >>ftp
set newpassword=
set/p newpassword=请输入新密码:
echo quote site pswd %oldpassword% %newpassword% >>ftp
echo bye >>ftp
echo.
echo 密码修改中,请稍等!
echo.

:: **************************************************************
:: * 此段为用命令行参数调用FTP文件中的参数，实现更改FTP密码功能 *
:: * 并将连接的结果输出到b.txt文件中 *
:: **************************************************************
@echo off
ftp.exe -s:ftp >b.txt

:: *********************************************************
:: * 此段为根据输出的结果判断更改密码是否成功,作出相应跳转 *
:: *********************************************************
for /f "skip=6 tokens=*" %%i in (b.txt) do (
    echo %%i|findstr "proceed.">nul && goto END
    echo %%i|findstr "530">nul && goto FAIL1
    echo %%i|findstr "connected.">nul && goto FAIL2
    echo %%i|findstr "later.">nul && goto FAIL3
)

:: **********************************************
:: * 此段为用户名或密码输入错误时显示的提示信息 *
:: **********************************************
:FAIL1
CLS
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo ************************************************
echo * 输入的用户名或密码错误,请重新输入 *
echo ************************************************
echo.
echo.
del ftp
del b.txt
goto START

:: *****************************************************************
:: * 此段为连接服务器出错时的提示信息,如果上面设置了手动输入地址 *
:: * 需要更改提示为:请确认与服务器连接是否正常或输入的地址是否正确 *
:: *****************************************************************
:FAIL2
CLS
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo ************************************************
echo * 无法连接到服务器,请确认与服务器连接是否正常 *
echo ************************************************
echo.
echo.
del ftp
del b.txt
goto START

:: **********************************************
:: *此段为服务器登录人数达到最大限制时的提示信息*
:: **********************************************
:FAIL3
CLS
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo ************************************************
echo *服务器登录人数达到最大限制数，请稍后在重试登录*
echo ************************************************
echo.
echo.
del ftp
del b.txt
goto START

:: **********************************
:: * 此段为密码更改成功时的提示信息 *
:: **********************************
:END
CLS
echo.
echo.
echo.
echo.
echo.
echo.
echo ************************************************
echo * 密码修改成功,请牢记您的新密码,按任意键退出 *
echo *                                              *
echo *                                              *
echo *   如密码遗忘请发邮件给我:                    *
echo ************************************************
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
del ftp
del b.txt
pause
exit