|
| 1 | +{-# LANGUAGE NamedFieldPuns #-} |
| 2 | + |
| 3 | +module Distribution.Client.CmdGenBounds |
| 4 | + ( genBounds |
| 5 | + , genBoundsCommand |
| 6 | + , genBoundsAction |
| 7 | + , GenBoundsFlags (..) |
| 8 | + , defaultGenBoundsFlags |
| 9 | + ) where |
| 10 | + |
| 11 | +import Distribution.Client.Compat.Prelude |
| 12 | +import Prelude () |
| 13 | + |
| 14 | +import qualified Data.Map as Map |
| 15 | + |
| 16 | +import Prelude () |
| 17 | + |
| 18 | +import Distribution.Client.Errors |
| 19 | + |
| 20 | +import Distribution.Client.ProjectPlanning hiding (pruneInstallPlanToTargets) |
| 21 | +import Distribution.Client.ProjectPlanning.Types |
| 22 | +import Distribution.Client.Types.ConfiguredId (confInstId) |
| 23 | +import Distribution.Client.Utils hiding (pvpize) |
| 24 | +import Distribution.InstalledPackageInfo (InstalledPackageInfo, installedComponentId) |
| 25 | +import Distribution.Package |
| 26 | +import Distribution.PackageDescription |
| 27 | +import Distribution.Simple.Utils |
| 28 | +import Distribution.Version |
| 29 | + |
| 30 | +import Distribution.Client.Setup (CommonSetupFlags (..), ConfigFlags (..), GlobalFlags (..)) |
| 31 | + |
| 32 | +-- Project orchestration imports |
| 33 | + |
| 34 | +import Distribution.Client.CmdErrorMessages |
| 35 | +import Distribution.Client.GenBounds |
| 36 | +import qualified Distribution.Client.InstallPlan as InstallPlan |
| 37 | +import Distribution.Client.NixStyleOptions |
| 38 | +import Distribution.Client.ProjectFlags |
| 39 | +import Distribution.Client.ProjectOrchestration |
| 40 | +import Distribution.Client.ScriptUtils |
| 41 | +import Distribution.Client.TargetProblem |
| 42 | +import Distribution.Simple.Command |
| 43 | +import Distribution.Simple.Flag |
| 44 | +import Distribution.Types.Component |
| 45 | +import Distribution.Verbosity |
| 46 | + |
| 47 | +-- | The data type for gen-bounds command flags |
| 48 | +data GenBoundsFlags = GenBoundsFlags {} |
| 49 | + |
| 50 | +-- | Default values for the gen-bounds flags |
| 51 | +defaultGenBoundsFlags :: GenBoundsFlags |
| 52 | +defaultGenBoundsFlags = GenBoundsFlags{} |
| 53 | + |
| 54 | +-- | The @gen-bounds@ command definition |
| 55 | +genBoundsCommand :: CommandUI (NixStyleFlags GenBoundsFlags) |
| 56 | +genBoundsCommand = |
| 57 | + CommandUI |
| 58 | + { commandName = "v2-gen-bounds" |
| 59 | + , commandSynopsis = "Generate dependency bounds for packages in the project." |
| 60 | + , commandUsage = usageAlternatives "v2-gen-bounds" ["[TARGETS] [FLAGS]"] |
| 61 | + , commandDescription = Just $ \_ -> |
| 62 | + "Generate PVP-compliant dependency bounds for packages in the project." |
| 63 | + , commandNotes = Just $ \pname -> |
| 64 | + "Examples:\n" |
| 65 | + ++ " " |
| 66 | + ++ pname |
| 67 | + ++ " v2-gen-bounds\n" |
| 68 | + ++ " Generate bounds for the package in the current directory " |
| 69 | + ++ "or all packages in the project\n" |
| 70 | + ++ " " |
| 71 | + ++ pname |
| 72 | + ++ " v2-gen-bounds pkgname\n" |
| 73 | + ++ " Generate bounds for the package named pkgname in the project\n" |
| 74 | + ++ " " |
| 75 | + ++ pname |
| 76 | + ++ " v2-gen-bounds ./pkgfoo\n" |
| 77 | + ++ " Generate bounds for the package in the ./pkgfoo directory\n" |
| 78 | + , commandDefaultFlags = defaultNixStyleFlags defaultGenBoundsFlags |
| 79 | + , commandOptions = |
| 80 | + removeIgnoreProjectOption |
| 81 | + . nixStyleOptions (const []) |
| 82 | + } |
| 83 | + |
| 84 | +-- | The action for the @gen-bounds@ command when used in a project context. |
| 85 | +genBoundsAction :: NixStyleFlags GenBoundsFlags -> [String] -> GlobalFlags -> IO () |
| 86 | +genBoundsAction flags targetStrings globalFlags = |
| 87 | + withContextAndSelectors RejectNoTargets Nothing flags targetStrings globalFlags OtherCommand $ \targetCtx ctx targetSelectors -> do |
| 88 | + let verbosity = fromFlagOrDefault normal (setupVerbosity $ configCommonFlags $ configFlags flags) |
| 89 | + |
| 90 | + baseCtx <- case targetCtx of |
| 91 | + ProjectContext -> return ctx |
| 92 | + GlobalContext -> return ctx |
| 93 | + ScriptContext path _ -> |
| 94 | + dieWithException verbosity $ |
| 95 | + GenBoundsDoesNotSupportScript path |
| 96 | + |
| 97 | + let ProjectBaseContext{distDirLayout, cabalDirLayout, projectConfig, localPackages} = baseCtx |
| 98 | + |
| 99 | + -- Step 1: Create the install plan for the project. |
| 100 | + (_, elaboratedPlan, _, _, _) <- |
| 101 | + rebuildInstallPlan |
| 102 | + verbosity |
| 103 | + distDirLayout |
| 104 | + cabalDirLayout |
| 105 | + projectConfig |
| 106 | + localPackages |
| 107 | + Nothing |
| 108 | + |
| 109 | + -- Step 2: Resolve the targets for the gen-bounds command. |
| 110 | + targets <- |
| 111 | + either (reportGenBoundsTargetProblems verbosity) return $ |
| 112 | + resolveTargets |
| 113 | + selectPackageTargets |
| 114 | + selectComponentTarget |
| 115 | + elaboratedPlan |
| 116 | + Nothing |
| 117 | + targetSelectors |
| 118 | + |
| 119 | + -- Step 3: Prune the install plan to the targets. |
| 120 | + let elaboratedPlan' = |
| 121 | + pruneInstallPlanToTargets |
| 122 | + TargetActionBuild |
| 123 | + targets |
| 124 | + elaboratedPlan |
| 125 | + |
| 126 | + let |
| 127 | + -- Step 4a: Find the local packages from the install plan. These are the |
| 128 | + -- candidates for which we will generate bounds. |
| 129 | + localPkgs :: [ElaboratedConfiguredPackage] |
| 130 | + localPkgs = mapMaybe (InstallPlan.foldPlanPackage (const Nothing) (\p -> Just p)) (InstallPlan.toList elaboratedPlan') |
| 131 | + |
| 132 | + -- Step 4b: Extract which versions we chose for each package from the pruned install plan. |
| 133 | + pkgVersionMap :: Map.Map ComponentId PackageIdentifier |
| 134 | + pkgVersionMap = Map.fromList (map (InstallPlan.foldPlanPackage externalVersion localVersion) (InstallPlan.toList elaboratedPlan')) |
| 135 | + |
| 136 | + externalVersion :: InstalledPackageInfo -> (ComponentId, PackageIdentifier) |
| 137 | + externalVersion pkg = (installedComponentId pkg, packageId pkg) |
| 138 | + |
| 139 | + localVersion :: ElaboratedConfiguredPackage -> (ComponentId, PackageIdentifier) |
| 140 | + localVersion pkg = (elabComponentId pkg, packageId pkg) |
| 141 | + |
| 142 | + let genBoundsActionForPkg :: ElaboratedConfiguredPackage -> [IO ()] |
| 143 | + genBoundsActionForPkg pkg = |
| 144 | + -- Step 5: Match up the user specified targets with the local packages. |
| 145 | + case Map.lookup (installedUnitId pkg) targets of |
| 146 | + Nothing -> [] |
| 147 | + Just tgts -> |
| 148 | + map (\(tgt, _) -> processBuildInfo verbosity tgt pkg pkgVersionMap) tgts |
| 149 | + |
| 150 | + -- Process each package to find the ones needing bounds |
| 151 | + let boundsActions = concatMap genBoundsActionForPkg localPkgs |
| 152 | + |
| 153 | + case boundsActions of |
| 154 | + [] -> notice verbosity "All bounds up-to-date" |
| 155 | + _ -> do |
| 156 | + notice verbosity boundsNeededMsg |
| 157 | + sequence_ (intersperse (putStrLn "") boundsActions) |
| 158 | + |
| 159 | +-- | Process a single BuildInfo to identify and report missing upper bounds |
| 160 | +processBuildInfo |
| 161 | + :: Verbosity |
| 162 | + -> ComponentTarget |
| 163 | + -> ElaboratedConfiguredPackage |
| 164 | + -> Map.Map ComponentId PackageIdentifier |
| 165 | + -> IO () |
| 166 | +processBuildInfo verbosity tgt pkg pkgVersionMap = do |
| 167 | + let pd = elabPkgDescription pkg |
| 168 | + -- Extract the build-depends for the right part of the cabal file. |
| 169 | + bi = buildInfoForTarget pd tgt |
| 170 | + |
| 171 | + -- We need to generate bounds if |
| 172 | + -- \* the dependency does not have an upper bound |
| 173 | + -- \* the dependency is not the same package as the one we are processing |
| 174 | + boundFilter dep = |
| 175 | + (not (hasUpperBound (depVerRange dep))) |
| 176 | + && packageName pd /= depPkgName dep |
| 177 | + |
| 178 | + -- The dependencies that need bounds. |
| 179 | + needBounds = map depPkgName $ filter boundFilter $ targetBuildDepends bi |
| 180 | + |
| 181 | + if null needBounds |
| 182 | + then |
| 183 | + notice |
| 184 | + verbosity |
| 185 | + ("Congratulations, all dependencies for " ++ prettyShow (packageName pd) ++ ":" ++ showComponentTarget (packageId pkg) tgt ++ " have upper bounds!") |
| 186 | + else do |
| 187 | + notice verbosity $ |
| 188 | + "For component " ++ prettyShow (packageName pd) ++ ":" ++ showComponentTarget (packageId pkg) tgt ++ ":" |
| 189 | + |
| 190 | + -- All the things we depend on. |
| 191 | + let componentDeps = elabLibDependencies pkg |
| 192 | + -- Match these up to package names, this is a list of Package name to versions. |
| 193 | + -- Now just match that up with what the user wrote in the build-depends section. |
| 194 | + depsWithVersions = mapMaybe (\cid -> Map.lookup (confInstId $ fst cid) pkgVersionMap) componentDeps |
| 195 | + isNeeded = hasElem needBounds . packageName |
| 196 | + thePkgs = filter isNeeded depsWithVersions |
| 197 | + |
| 198 | + let padTo = maximum $ map (length . unPackageName . packageName) thePkgs |
| 199 | + |
| 200 | + traverse_ (notice verbosity . (++ ",") . showBounds padTo) thePkgs |
| 201 | + |
| 202 | +buildInfoForTarget :: PackageDescription -> ComponentTarget -> BuildInfo |
| 203 | +buildInfoForTarget pd (ComponentTarget cname _) = componentBuildInfo $ getComponent pd cname |
| 204 | + |
| 205 | +-- | This defines what a 'TargetSelector' means for the @gen-bounds@ command. |
| 206 | +-- Copy of selectPackageTargets from CmdBuild.hs |
| 207 | +selectPackageTargets |
| 208 | + :: TargetSelector |
| 209 | + -> [AvailableTarget k] |
| 210 | + -> Either TargetProblem' [k] |
| 211 | +selectPackageTargets targetSelector targets |
| 212 | + -- If there are any buildable targets then we select those |
| 213 | + | not (null targetsBuildable) = |
| 214 | + Right targetsBuildable |
| 215 | + -- If there are targets but none are buildable then we report those |
| 216 | + | not (null targets) = |
| 217 | + Left (TargetProblemNoneEnabled targetSelector targets') |
| 218 | + -- If there are no targets at all then we report that |
| 219 | + | otherwise = |
| 220 | + Left (TargetProblemNoTargets targetSelector) |
| 221 | + where |
| 222 | + targets' = forgetTargetsDetail targets |
| 223 | + targetsBuildable = |
| 224 | + selectBuildableTargetsWith |
| 225 | + (buildable targetSelector) |
| 226 | + targets |
| 227 | + |
| 228 | + -- When there's a target filter like "pkg:tests" then we do select tests, |
| 229 | + -- but if it's just a target like "pkg" then we don't build tests unless |
| 230 | + -- they are requested by default (i.e. by using --enable-tests) |
| 231 | + buildable (TargetPackage _ _ Nothing) TargetNotRequestedByDefault = False |
| 232 | + buildable (TargetAllPackages Nothing) TargetNotRequestedByDefault = False |
| 233 | + buildable _ _ = True |
| 234 | + |
| 235 | +-- | For a 'TargetComponent' 'TargetSelector', check if the component can be |
| 236 | +-- selected. Copy of selectComponentTarget from CmdBuild.hs |
| 237 | +selectComponentTarget |
| 238 | + :: SubComponentTarget |
| 239 | + -> AvailableTarget k |
| 240 | + -> Either TargetProblem' k |
| 241 | +selectComponentTarget = selectComponentTargetBasic |
| 242 | + |
| 243 | +-- | Report target problems for gen-bounds command |
| 244 | +reportGenBoundsTargetProblems :: Verbosity -> [TargetProblem'] -> IO a |
| 245 | +reportGenBoundsTargetProblems verbosity problems = |
| 246 | + reportTargetProblems verbosity "gen-bounds" problems |
0 commit comments