Dynamics 365 Finance and Operations’ta varyantlı ürünlerde doğru birim dönüşümünü sağlamak için EcoResProductUnitConverter::convertGivenUnitSymbolsForReleasedProduct() metodunu kullanmak gerekir. Bu metod, ürün varyantına özel tanımlı dönüşüm faktörlerini dikkate alır ve standart UnitOfMeasureConverter::convert() metoduna göre daha doğru sonuçlar üretir.

📘 Temel Kullanım

SalesQty documentSalesQty = EcoResProductUnitConverter::convertGivenUnitSymbolsForReleasedProduct(
    salesLine.ItemId,
    salesLine.InventDimId,
    salesLine.SalesQty,
    salesLine.SalesUnit,
    salesLine.ABCDocumentUnitId,
    NoYes::Yes
);

SalesPrice documentSalesPrice = decRound(salesLine.LineAmount / documentOtherSalesQty, 4);

Parametreler:

• ItemId: Released product kodu
• InventDimId: Stok boyut bilgisi (depo, site vb.)
• SalesQty: Dönüştürülecek miktar
• SalesUnit: Kaynak birim sembolü (ör. "ADET")
• ABCDocumentUnitId: Hedef birim sembolü (ör. "KG")
• NoYes::Yes: Mutlak değeri yuvarlama (opsiyonel)

⚙️ Avantajlar

• Variant (ürün varyantı) bazlı doğru dönüşüm
• Item-level UoM kurallarını destekler
• Depo/site bazlı farklılıkları dikkate alabilir

💡 Özet

Varyantlı ürünlerde EcoResProductUnitConverter::convertGivenUnitSymbolsForReleasedProduct() kullanmak, stok, sipariş ve maliyet hesaplarında birim farklılıklarından doğan hataları önler.

Originally published at https://bayramcetin.com on November 12, 2025.

Dynamics 365 projelerinde geliştirme yaparken best practice (BP) ihlallerini ve olası uyumsuzlukları tespit etmek için CAR (Customization Analysis Report) oldukça faydalı bir araçtır. Bu rapor sayesinde geliştirdiğiniz modeldeki hataları erken fark edip, kod kalitesini artırabilirsiniz.

🧩 CAR Raporu Nasıl Oluşturulur?

1. CMD’yi yönetici (Run as Administrator) olarak açın.
2. Aşağıdaki komutu kendi model adınıza göre düzenleyip çalıştırın:

K:\AosService\PackagesLocalDirectory\bin\xppbp.exe -metadata="K:\AosService\PackagesLocalDirectory" -all -model="ABCModel" -xmlLog=C:\temp\BPCheckLogcd.xml -module="ABCModel" -car=c:\temp\ABCModel_CAReport.xlsx

3. Komut tamamlandığında belirttiğiniz dizinde bir .xlsx dosyası (CAR raporu) oluşacaktır.

Raporu inceledikten sonra listelenen BP (Best Practice) ve Issue maddelerini düzenleyebilirsiniz.

💡Tüm bu adımlar, projenizin kod kalitesi, sürdürülebilirliği ve upgrade uyumluluğu için kritik öneme sahiptir.

👉 Microsoft dokümantasyonunu da inceleyebilirsiniz

Originally published at https://bayramcetin.com on November 7, 2025.

Dynamics 365 Finance and Operations (D365 FO) geliştiricileri için metin (string) işlemleri, günlük geliştirme süreçlerinin vazgeçilmez parçalarındandır. Kullanıcı girdilerini kontrol etmek, verileri parçalara ayırmak veya formatlamak gibi birçok senaryoda bu işlemler karşımıza çıkar.

Bu yazıda, X++ dilinde sıkça kullanılan bazı temel metin komutlarını ve bunların pratik örneklerini inceleyeceğiz:

strfmt

Belirli bir format içerisinde birden fazla değeri birleştirmek için kullanılır.

str name = "Ahmet";
int age = 30;
str result = strFmt("Ad: %1 - Yaş: %2", name, age);
// Sonuç: "Ad: Ahmet - Yaş: 30"

Özellikle bilgi mesajları, log kayıtları ya da çıktılar oluştururken hayat kurtarır.

strlen

Bir metnin uzunluğunu döner.

str text = "Dynamics365";
int length = strlen(text);
// Sonuç: 11

Boş mu değil mi kontrolü yaparken veya maksimum karakter sınırlamalarını aşmamak için kullanılır.

strFind

Bir metin içinde, başka bir metnin yerini (başlangıç indeksini) bulur.

str fullText = "Dynamics365";
int index = strFind(fullText, "365", 1, strlen(fullText));
// Sonuç: 9

Bulunamazsa 0 döner. Özellikle doğrulama veya ayrıştırma işlemlerinde faydalıdır.

subStr

Bir metnin belirli bir bölümünü almak için kullanılır.

str text = "Dynamics365";
str part = subStr(text, 1, 8);
// Sonuç: "Dynamics"

Genellikle sabit formatlı metinleri ayrıştırmak için kullanılır (örneğin fatura numaralarından tarih çekmek).

strDel

Bir metinden, belirli bir aralıktaki karakterleri siler.

str text = "Dynamics365";
str result = strDel(text, 9, 3);
// Sonuç: "Dynamics"

Bu örnekte 9. karakterden başlayarak 3 karakter silindi. Genellikle istenmeyen karakterleri temizlemek için idealdir.

strSplit

Bir metni, belirli bir ayırıcıya göre parçalara ayırır. X++ içinde strSplit metodu Global sınıfında yer alır.

List parts = strSplit("Ahmet,Mehmet,Ayşe", ",");
ListEnumerator enumerator = parts.getEnumerator();
while (enumerator.moveNext())
{
    info(strFmt("İsim: %1", enumerator.current()));
}

Sonuç:

İsim: Ahmet  
İsim: Mehmet  
İsim: Ayşe

CSV ayrıştırma, isim-soyisim ayırma gibi işlemlerde oldukça kullanışlıdır.

🎯 Gerçek Hayattan Senaryo Örneği

str fullName = "Çetin, Bayram";
List nameParts = strSplit(fullName, ",");
str surname = strLTrim(nameParts.get(1));
str name = strLTrim(nameParts.get(2));

info(strFmt("Ad: %1 - Soyad: %2", name, surname));

Bu örnekte kullanıcıdan gelen “Soyad, Ad” formatındaki veri doğru şekilde parçalanıyor ve ekrana düzgün bir şekilde yazdırılıyor.

📝 Sonuç

Metin işlemleri Dynamics 365 projelerinde küçük ama kritik roller üstlenir. strFmt, strFind, strDel, strSplit gibi komutlar sayesinde karmaşık veri işleme ihtiyaçları bile basit çözümlerle karşılanabilir. Bu fonksiyonları iyi bilmek, hem kod kalitesini artırır hem de daha okunabilir ve yönetilebilir çözümler üretmemizi sağlar.

Originally published at https://bayramcetin.com on June 20, 2025.

Dynamics 365 Finance and Operations’ta iş akışları, kurumsal süreçlerin düzenli ve kontrol edilebilir bir şekilde ilerlemesini sağlayan kritik bileşenlerden biridir. İş akışı içinde kullanıcı hareketlerini takip etmek, bu hareketlere bağlı kurallar tanımlamak ve bu sayede süreci otomatikleştirmek mümkün olur.

Bu yazıda, iş akışına gönderen, onaylayan ve yeniden atanan kullanıcıların nasıl takip edileceğini gösteren display metotlar üreteceğiz. Bu metotları ilgili tabloya ekleyerek, kullanıcı hareketlerini anlık olarak görüntüleyebilir ve iş akışı kurallarına entegre edebilirsiniz.

1. İş Akışı Kullanıcı Hareketlerini Takip Etmek

Dynamics 365'te iş akışı hareketlerini kaydeden iki temel tablo vardır:

• WorkflowTrackingTable: İş akışı hareketlerini saklayan tablo.
• WorkflowTrackingStatusTable: İş akışının mevcut durumunu takip eden tablo.

Bu tabloları kullanarak iş akışına gönderen, onaylayan ve atanan kullanıcıyı bulabiliriz.

1.1 İş Akışını Onaylayan Kullanıcı

Bu metot, ilgili kayıt üzerinde iş akışını en son onaylayan kullanıcıyı getirir.

/// <summary>
/// İş akışını onaylayan kullanıcı
/// </summary>
display UserId workflowApprovalUser()
{
    WorkflowTrackingStatusTable workflowTrackingStatusTable;
    WorkflowTrackingTable       workflowTrackingTable;

    select firstOnly workflowTrackingTable order by CreatedDateTime desc
    exists join workflowTrackingStatusTable
     where workflowTrackingStatusTable.RecId == workflowTrackingTable.WorkflowTrackingStatusTable
        && workflowTrackingStatusTable.ContextTableId == this.TableId
        && workflowTrackingStatusTable.ContextRecId == this.RecId
        && workflowTrackingTable.TrackingType == WorkflowTrackingType::Approval;

    return workflowTrackingTable.User;
}

1.2 İş Akışına Gönderen Kullanıcı

Bir iş akışının kim tarafından başlatıldığını anlamak için aşağıdaki metodu kullanabiliriz:

/// <summary>
/// İş akışına gönderen kullanıcı
/// </summary>
display UserId workflowSubmittedUser()
{
    WorkflowTrackingStatusTable workflowTrackingStatusTable;
    WorkflowTrackingTable       workflowTrackingTable;

    select firstOnly workflowTrackingTable order by CreatedDateTime desc
    exists join workflowTrackingStatusTable
     where workflowTrackingStatusTable.RecId == workflowTrackingTable.WorkflowTrackingStatusTable
        && workflowTrackingStatusTable.ContextTableId == this.TableId
        && workflowTrackingStatusTable.ContextRecId == this.RecId
        && workflowTrackingTable.TrackingType == WorkflowTrackingType::Submission;

    return workflowTrackingTable.User;
}

Bu metot, iş akışını başlatan (ilk gönderen) kullanıcıyı getirir.

1.3 İş Akışına Son Atanan Kullanıcı

Bazen iş akışı bir başka kullanıcıya atanabilir. Bu durumda, son atanan kullanıcıyı bulmak için şu metodu kullanabiliriz:

/// <summary>
/// İş akışına son atanan kullanıcı
/// </summary>
display UserId workflowReassignedUser()
{
    WorkflowTrackingStatusTable workflowTrackingStatusTable;
    WorkflowTrackingTable       workflowTrackingTable;

    select firstOnly workflowTrackingTable order by CreatedDateTime desc
    exists join workflowTrackingStatusTable
     where workflowTrackingStatusTable.RecId == workflowTrackingTable.WorkflowTrackingStatusTable
        && workflowTrackingStatusTable.ContextTableId == this.TableId
        && workflowTrackingStatusTable.ContextRecId == this.RecId
        && workflowTrackingTable.TrackingType == WorkflowTrackingType::Creation;

    return workflowTrackingTable.User;
}

Bu metot, iş akışının son olarak hangi kullanıcıya atandığını getirir.

Sonuç

Bu display metotlarını kullanarak iş akışı hareketlerini kolayca takip edebilir ve bunlara dayalı çeşitli iş kuralları tanımlayabilirsiniz. Bu sayede iş akışınızı daha dinamik ve kural bazlı hale getirebilirsiniz.

Originally published at https://bayramcetin.com on February 4, 2025.

Dynamics 365 Finance and Operations’da arama işlemlerini özelleştirmek ve esnek hale getirmek için SysQuery::valueLike() metodu oldukça kullanışlıdır. Bu blog yazısında, LIKE operatörünü kullanarak bir veritabanı sorgusunu nasıl oluşturabileceğinizi ve sonuçları nasıl filtreleyebileceğinizi göstereceğim.

Kod Örneği

Aşağıdaki örnekte, bir LineOfBusiness tablosundaki açıklama (Description) alanında bir kelime ya da karakter dizisi geçen kayıtları sorgulamak için SysQuery::valueLike() metodunu kullanıyoruz:

public static LineOfBusiness runQueryLike(Description _description)
{
    LineOfBusiness lineOfBusiness;

    Query query = new Query();
    QueryBuildDataSource qbds = query.addDataSource(tableNum(LineOfBusiness));

    QueryBuildRange qbr = qbds.addRange(fieldNum(LineOfBusiness, Description));
    qbr.value(SysQuery::valueLike(_description));

    QueryRun qr = new QueryRun(query);

    while(qr.next())
    {
        lineOfBusiness = qr.get(tableNum(LineOfBusiness));

        return lineOfBusiness;
    }

    return lineOfBusiness;
}

Bu Kod Ne Yapar?

• SysQuery::valueLike(_description): Gelen _description parametresine göre, SQL LIKE operatörünü kullanarak bir filtre uygular.
• QueryBuildDataSource ve QueryBuildRange: Sorgunun temel yapı taşlarını oluşturur. QueryBuildRange, belirli bir alan üzerinde filtre uygulamak için kullanılır.
• Dönen Değer: Sorguya uyan ilk kayıt döndürülür.

Önemli Notlar

• LIKE operatörü, büyük/küçük harf duyarlılığına dikkat eder. Bu nedenle, ihtiyaca göre büyük/küçük harf duyarlılığını kaldırmak için ek kontroller yapılabilir.
• Performans açısından dikkatli olunmalıdır. Çok geniş kapsamlı bir LIKE araması, büyük tablolar üzerinde yavaş çalışabilir.

Originally published at https://bayramcetin.com on December 18, 2024.

Dynamics 365 Finance and Operations’ta Özel Workflow Katılımcı Sağlayıcı Nasıl Oluşturulur?

Dynamics 365 Finance and Operations’ta Workflow Participant Provider, iş akışlarında belirli bir adım için uygun kullanıcıları veya grupları tanımlamak için kullanılır. Bu yazıda, satınalma taleplerini yöneticilere atayan bir sınıfın nasıl oluşturulup iş akışına bağlanacağını adım adım ele alacağız.

1. Sınıfın Tanımı

Aşağıdaki sınıf, satınalma talep biriminin yöneticisini belirler ve iş akışı katılımcısı olarak atar:

class ETGPurchTableTemplateRequesterParticipantProvider implements WorkflowParticipantProvider
{
    public WorkflowParticipantTokenList getParticipantTokens()
    {
        WorkflowParticipantTokenList        tokenList = WorkflowParticipantTokenList::construct();

        tokenList.add("ETGPurchRequesterWorkflowUser", "Satınalma Talep Birimi");

        return tokenList;
    }

    public WorkflowUserList resolve(WorkflowContext _context, WorkflowParticipantToken _participantTokenName)
    {
        WorkflowUserList userList = WorkflowUserList::construct();

        if  (!_participantTokenName)
        {
            throw error("Participant token bulunamadı!");
        }

        if  (_participantTokenName == "ETGPurchRequesterWorkflowUser")
        {
            PurchTable purchTable = PurchTable::findRecId(_context.parmRecId());

            HcmPositionRecId positionRecId = HcmWorkerHelper::getWorkerPrimaryPositionAssignment(purchTable.Requester).Position;
            HcmPositionRecId parentPositionRecId = HcmPositionHierarchy::findByPosition(positionRecId).ParentPosition;
            HcmWorkerRecId parentWorkerRecId = HcmPositionWorkerAssignment::findByPosition(parentPositionRecId).Worker;

            UserId userId = HcmWorker::findPersonUser(parentWorkerRecId).User;

            if (userId)
            {
                userList.add(userId);
            }
            else
            {
                throw error(strFmt("%1 Satınalma Talep Birimi üst yöneticisi bulunamadı.", purchTable.PurchId));
            }
        }

        return userList;
    }

}

2. Workflow Participant Assignment Provider Tanımlama

Sınıfı iş akışına bağlamak için bir Workflow Participant Assignment Provider oluşturun:

1. Yeni Provider Ekleyin:

• Name: ETGPurchTableTemplateRequesterParticipantProvider

2. Özellikleri Ayarlayın:

• Label: Satınalma Talep Birimi
• Provider Class: ETGPurchTableTemplateRequesterParticipantProvider
• Workflow Types: PurchTableTemplate

3. Kaydedin ve Derleyin.

3. İş Akışına Bağlama

1. Dynamics 365'te PurchTableTemplate iş akışını açın.
2. Bir “Approval” adımı ekleyin veya düzenleyin.
3. Assignment Type olarak “Participant” seçin.
4. Provider alanında yeni tanımladığınız sağlayıcıyı seçin.
5. İş akışını kaydedin ve doğrulayın.

Sonuç

Bu işlemle, iş akışınız satınalma taleplerini otomatik olarak doğru yöneticilere atayacak şekilde özelleştirilmiştir.

Originally published at https://bayramcetin.com on December 5, 2024.

DocuRef, Dynamics 365 Finance and Operations’da, belirli bir kayıtla ilişkilendirilmiş belgeleri veya notları saklamak için kullanılan bir tablodur. Geliştirme sırasında, bir kaydın belirli bir türde bir DocuRef kaydına sahip olup olmadığını kontrol etmek gerekebilir. Bunun için aşağıdaki gibi bir metod kullanabilirsiniz:

public static boolean isDocuRefRecord(Common _common, DocuTypeId _typeId)
{
    boolean ret = false;
    DocuRef docuRef;

    select firstonly docuRef
     where docuRef.RefCompanyId == _common.DataAreaId
        && docuRef.RefTableId == _common.TableId
        && docuRef.RefRecId == _common.RecId
        && docuRef.TypeId == _typeId;

    if(docuRef)
        ret = true;

    return ret;
}

Metodun İşlevi

Bu metod, _common parametresiyle verilen tablo kaydının, _typeId ile belirtilen türde bir DocuRef kaydına sahip olup olmadığını kontrol eder. Eğer ilgili kayıt varsa, true döner; aksi takdirde false.

Kullanım Alanları

• Kayıtların ilişkilendirilmiş belgelerini kontrol etmek.
• Kullanıcıya, bir işlem yapılmadan önce belirli bir doküman ilişkisinin varlığı hakkında bilgi vermek.
• Doküman yönetim süreçlerinde doğrulama yapmak.

Dynamics 365 geliştirmelerinde bu gibi yardımcı metodlar, iş süreçlerinizi daha verimli ve yönetilebilir hale getirebilir.

Originally published at https://bayramcetin.com on December 4, 2024.

Dynamics 365'te Dinamik Alan Değişikliklerini İzleme ve Kayıt Altına Alma

Dynamics 365 Finance and Operations (D365FO), kullanıcıların iş süreçlerini dijitalleştirirken verilerin güvenliği ve doğruluğunu sağlamak adına önemli bir rol oynar. Ancak, veritabanındaki alanlarda yapılan değişikliklerin izlenmesi, özellikle finansal ve bütçe verileri gibi kritik bilgiler için hayati öneme sahiptir. Bu yazıda, D365'te alan bazında yapılan değişikliklerin nasıl dinamik bir şekilde tespit edileceğini ve kaydedileceğini göstereceğiz.

Değişikliklerin izlenmesi için geliştirilen yöntem, iki kaydın karşılaştırılması ve her alanın değerinin kontrol edilmesi üzerine kuruludur. Bu sayede, eski ve yeni veri arasındaki farklar dinamik bir şekilde belirlenir ve her değişiklik, sistemde loglanarak izlenebilir hale gelir. Özellikle logField ve createLog metotları ile bu sürecin nasıl işlediğini ve değişikliklerin nasıl kaydedildiğini inceleyeceğiz.

public static void logField(ETGBudgetEntryLine _lineOrig, ETGBudgetEntryLine _lineThis)
{
    DictTable   dictTable = new DictTable(_lineOrig.TableId);
    FieldId     fieldId   = dictTable.fieldNext(0);
    //FieldName   fieldName = dictTable.fieldName(fieldId);
    DictField   dictField;

    while (fieldId && ! isSysId(fieldId))
    {
        dictField = dictTable.fieldObject(fieldId);

        if(_lineOrig.(fieldId) != _lineThis.(fieldId))
        {
            ETGBudgetEntryLineHistory::createLog(_lineOrig, _lineThis, fieldId);
        }

        fieldId = dictTable.fieldNext(fieldId);
        //fieldName = dictTable.fieldName(fieldId);
    }
}

logField Metodu

Bu metodun görevi, iki kayıt arasındaki farkları tespit etmektir.

Metodun işleyişi:

1. Tablo ve Alanları Listeleme:

• _lineOrig.TableId kullanılarak DictTable nesnesi oluşturuluyor. Bu, tablo yapısını dinamik olarak incelemek için kullanılır.
• fieldNext(0) ile ilk alan ID'si alınıyor, ardından tüm alanlar sırayla döngü ile kontrol ediliyor.

2. Sistem Alanlarını Hariç Tutma:

• isSysId(fieldId) kontrolü ile sistem alanları (örneğin RecId, DataAreaId gibi) hariç tutuluyor.

3. Alanların Değerlerini Karşılaştırma:

• _lineOrig.(fieldId) ve _lineThis.(fieldId) ifadeleri, her alanın değerini dinamik olarak alır. Eğer iki kayıt arasında bu alanın değeri farklıysa:
• createLog metodu çağrılarak değişim kaydedilir.

public static void createLog(ETGBudgetEntryLine _budgetEntryLineOld, ETGBudgetEntryLine _budgetEntryLineNew, FieldId _fieldId)
{
    ETGBudgetEntryLineHistory history;

    ttsBegin;
    history.clear();
    history.BudgetEntryId = _budgetEntryLineNew.BudgetEntryId;
    history.LineNumber = _budgetEntryLineNew.LineNumber;
    history.ChangeField = fieldId2pname(_budgetEntryLineNew.TableId, _fieldId);
    history.OldFieldValue = _budgetEntryLineOld.(_fieldId);
    history.NewFieldValue = _budgetEntryLineNew.(_fieldId);
    history.ChangeUser = curUserId();
    history.ChangeDateTime = DateTimeUtil::getSystemDateTime();
    history.insert();
    ttsCommit;
}

createLog Metodu

Bu metodun görevi, değişikliklerin kaydedilmesi için bir log (kayıt) oluşturmak.

Metodun işleyişi:

Log Kaydı Hazırlama:

1. ETGBudgetEntryLineHistory Bu tablo, değişiklik geçmişini tutuyor.
2. Yeni bir log kaydı oluşturuluyor ve aşağıdaki değerler atanıyor:

• BudgetEntryId ve LineNumber: Değişiklik yapılan kaydın kimlik bilgileri.
• ChangeField: Değişen alanın etiket bilgisi(Label)
• OldFieldValue ve NewFieldValue: Eski ve yeni değerler atanıyor.
• ChangeUser ve ChangeDateTime: Değişiklik yapan kullanıcı ve değişiklik yaptığı zaman bilgileri tutuluyor.

Özetle: Bu kod, iki tablo kaydını karşılaştırarak değişen alanları tespit eder ve bu değişiklikleri bir log tablosuna yazar. Değişiklik takibi veya hata analizi gibi senaryolarda oldukça faydalı olabilir. Kritik verilerin, özellikle finansal ve bütçe verilerinin izlenmesi gereken durumlarda bu yöntem etkin bir şekilde kullanılabilir.

Originally published at https://bayramcetin.com on November 26, 2024.

Dynamics 365'te SQL Sorguları ile TableId ve FieldId bilgilerini Nasıl Elde Edersiniz?

Dynamics 365 Finance and Operations’ta tablolara ve alanlarına dair meta verilere erişmek, özel geliştirmeler ve analizler için kritik önem taşır. Aşağıdaki sorgular, tablo ve alan bilgilerini SQL üzerinden nasıl alabileceğinizi gösterir:

1. Bir Tablo Bilgisini Almak

 SELECT Id, Name, SqlName 
 FROM SYSTABLEIDVIEW 
 WHERE Name = 'DirPartyTable';

Bu sorgu, DirPartyTable tablosunun sistemdeki benzersiz kimliğini (Id) ve SQL Server üzerindeki fiziksel adını (SqlName) getirir.

2. Bir Tabloya Ait Alan Bilgilerini Listelemek

 SELECT Id, FIELDID, Name, SqlName 
 FROM SysTableFieldIdView 
 WHERE Id = '2303';

Tablo kimliği 2303 olan tabloya ait tüm alanların isimlerini, sistem kimliklerini ve SQL karşılıklarını listelemek için bu sorguyu kullanabilirsiniz.

Bu sorgular, tablolar ve alanlar üzerinde detaylı analiz yapmayı kolaylaştırır ve özel geliştirmelerde zaman kazandırır.

Originally published at https://bayramcetin.com on November 26, 2024.

Dynamics 365 Finance and Operations uygulamalarında, kullanıcıların veri girişi sırasında seçim yapmalarını kolaylaştırmak için dialog alanları sıkça kullanılır. Ancak, standart dialog alanlarındaki lookup’lar genellikle tek seçimle sınırlıdır. Bu yazıda, bir dialog alanına çoklu seçim özelliği eklemek için nasıl bir yöntem kullanabileceğinizi adım adım açıklayacağız.

Kullanılacak Yöntem: SysLookupMultiSelectGrid

SysLookupMultiSelectGrid sınıfı, Dynamics 365'te çoklu seçim yapılabilir bir grid oluşturmak için kullanılır. Bu sınıfı, dialog'un bir alanında çoklu seçim sağlayan bir lookup ile entegre edeceğiz.

Adım 1: Dialog Alanını Tanımlama

Dialog alanını oluşturmak için bir Dialog nesnesi kullanılır. Aşağıda, bir dialog'un nasıl oluşturulacağı ve bir alanın lookup özelliğinin nasıl geçersiz kılınacağı gösterilmiştir:

private boolean dialog()
{
    Dialog dialog = new Dialog("Personelleri ekle");
    DialogField field  = dialog.addField(extendedTypeStr(String500), "Personel");

    field.registerOverrideMethod(methodStr(FormStringControl, lookup),
        methodStr(BCResponsibleAddMultiLine, lookupPerson), this);
    
    if(dialog.run())
    {
        if (!field.value())
            throw warning("Personelleri seçiniz.");
    
        dialogValue = field.value();

        return true;
    }

    return false;
}

Yukarıdaki kodda:

• Dialog nesnesi ile bir dialog penceresi oluşturuluyor.
• registerOverrideMethod kullanılarak, ilgili alanın lookup metodu geçersiz kılınıyor ve kendi lookupPerson metodumuz ile değiştiriliyor.

Adım 2: Çoklu Seçim Lookup’ını Oluşturma

Dialog alanına çoklu seçim özelliği eklemek için SysLookupMultiSelectGrid sınıfını kullanacağız. İşte örnek kod:

public void lookupPerson(FormStringControl _formControl)
{
    Query query = new Query();
    QueryBuildDataSource queryBuildDataSource = query.addDataSource(tableNum(HcmWorker));

    queryBuildDataSource.addSelectionField(fieldNum(HcmWorker, Person));

    container Person;

    SysLookupMultiSelectGrid::lookup(query,_formControl,_formControl,_formControl, Person);
}

Bu metotta:

• Query nesnesi ile HcmWorker tablosundan veriler alınıyor.
• SysLookupMultiSelectGrid::lookup metodu, verilen sorgu ile çoklu seçim yapılabilir bir grid oluşturuyor.

Adım 3: Seçimlerin İşlenmesi

Kullanıcının yaptığı seçimler, dialog kapandıktan sonra işlenmelidir. Aşağıdaki kodda, seçilen değerlerin nasıl işleneceği gösterilmiştir:

private void run()
{
   if(this.validate() && this.dialog())
   {
      BCResponsible bcResponsibleNew;
      RecId person;
      List strlist = new List(Types::Int64);
    
      strlist = strSplit(dialogValue, ";");
    
      ListIterator it = new ListIterator(strlist);
    
      ttsbegin;
      while (it.more())
      {
         person = it.value();
      
         bcResponsibleNew.clear();
         bcResponsibleNew.Number = record.Number;
         bcResponsibleNew.PersonnelHcm = HcmWorker::findByPerson(person).RecId;
         bcResponsibleNew.insert();
      
         it.next();
      }
    
      ttscommit;
      info(strFmt("Personeller oluşturuldu."));
   }
}

Bu kodda:

• strSplit ile dialog alanından alınan değerler ayrıştırılıyor.
• Her bir seçim işlenerek, ilgili tabloya kayıt ekleniyor.

Sonuç

Bu yöntem ile Dynamics 365 uygulamalarında dialog alanlarında çoklu seçim yapabilen bir lookup oluşturabilirsiniz. SysLookupMultiSelectGrid sınıfı, kullanıcılara esnek ve kullanıcı dostu bir deneyim sunarak, iş süreçlerinizi hızlandırabilir.

Umarım bu yazı, Dynamics 365 projelerinizde çoklu seçim özellikleri eklemek için size ilham verir! 😊

Tam Kod

class BCResponsibleAddMultiLine
{
    BCTable record;

    str dialogValue;

    public void lookupPerson(FormStringControl _formControl)
    {
        Query query = new Query();
        QueryBuildDataSource queryBuildDataSource = query.addDataSource(tableNum(HcmWorker));

        queryBuildDataSource.addSelectionField(fieldNum(HcmWorker, Person));

        container Person;

        SysLookupMultiSelectGrid::lookup(query,_formControl,_formControl,_formControl, Person);
    }

    private boolean dialog()
    {
        Dialog dialog = new Dialog("Personelleri ekle");
        DialogField field  = dialog.addField(extendedTypeStr(String500), "Personel");

        field.registerOverrideMethod(methodStr(FormStringControl, lookup),
            methodStr(BCResponsibleAddMultiLine, lookupPerson), this);
        
        if(dialog.run())
        {
            if (!field.value())
                throw warning("Personelleri seçiniz.");
        
            dialogValue = field.value();

            return true;
        }
    
        return false;
    }

    private void run()
    {
        if(this.validate() && this.dialog())
        {
            BCResponsible bcResponsibleNew;
            RecId person;
            List strlist = new List(Types::Int64);

            strlist = strSplit(dialogValue, ";");

            ListIterator it = new ListIterator(strlist);

            ttsbegin;
            while (it.more())
            {
                person = it.value();

                bcResponsibleNew.clear();
                bcResponsibleNew.Number = record.Number;
                bcResponsibleNew.PersonnelHcm = HcmWorker::findByPerson(person).RecId;
                bcResponsibleNew.insert();

                it.next();
            }

            ttscommit;
            info(strFmt("Personeller oluşturuldu."));
        }
    }

    private boolean validate()
    {
        boolean isValid = true;

        return isValid;
    }

    public BCTable parmRecord(BCTable _record = record)
    {
        record = _record;
        return record;
    }

    public void new()
    {
        
    }

    public static BCResponsibleAddMultiLine construct()
    {
        return new BCResponsibleAddMultiLine();
    }

    public static void main(Args _args)
    {
        if (! _args || ! _args.dataset() || ! _args.record() ||
            _args.record().TableId != tablenum(BCTable))
        {
            throw error(Error::missingRecord(funcname()));
        }
        
        BCResponsibleAddMultiLine process = BCResponsibleAddMultiLine::construct();
        process.parmRecord(_args.record());
        process.run();
    }

}

Originally published at https://bayramcetin.com on November 7, 2024.