1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
|
/****************************************************************************
**
** Copyright (C) 2024 The Qt Company Ltd.
** Contact: https://www.qt.io/licensing/
**
** This file is part of Qt Quick Studio Components.
**
** $QT_BEGIN_LICENSE:GPL$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see https://www.qt.io/terms-conditions. For further
** information use the contact form at https://www.qt.io/contact-us.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 3 or (at your option) any later version
** approved by the KDE Free Qt Foundation. The licenses are as published by
** the Free Software Foundation and appearing in the file LICENSE.GPL3
** included in the packaging of this file. Please review the following
** information to ensure the GNU General Public License requirements will
** be met: https://www.gnu.org/licenses/gpl-3.0.html.
**
** $QT_END_LICENSE$
**
****************************************************************************/
import QtQuick
import QtQuick.Shapes
/*!
\qmltype PieItem
\inqmlmodule QtQuick.Studio.Components
\since QtQuick.Studio.Components 1.0
\inherits Shape
\brief A pie.
The Pie type is used to create a pie slice, a pie that is missing slices, or just the pie stroke
(similar to an \l ArcItem), depending on the \l begin and \l end property values and the
\l hideLine value.
The filling of the pie is painted using either a solid fill color, specified using the
\l fillColor property, or a gradient, defined using one of the \l ShapeGradient subtypes and set
using the \l gradient property. If both a color and a gradient are specified, the gradient is
used.
The \l strokeColor, \l strokeWidth, and \l strokeStyle properties specify the appearance of the
pie outline. The \l dashPattern and \l dashOffset properties specify the appearance of dashed
lines.
The \l capStyle property specifies whether line ends are square or rounded.
\section2 Example Usage
You can use the Pie component in \QDS to create different kinds of pies.
\image studio-pie.webp
The QML code looks as follows:
\code
PieItem {
id: pieSlice
x: 920
y: 416
strokeWidth: -1
antialiasing: true
strokeColor: "gray"
fillColor: "light gray"
}
PieItem {
id: pie
x: 1118
y: 407
end: 300
fillColor: "#d3d3d3"
strokeColor: "#808080"
antialiasing: true
}
PieItem {
id: pieStroke
x: 1022
y: 548
fillColor: "#00ffffff"
strokeWidth: 4
capStyle: 32
hideLine: true
end: 300
strokeColor: "#808080"
antialiasing: true
}
\endcode
*/
Shape {
id: root
width: 100
height: 100
/*!
\include CommonItemDescriptions.qdocinc {component-gradient} {pie}
*/
property alias gradient: path.fillGradient
/*!
\include CommonItemDescriptions.qdocinc component-joinStyle
*/
//property alias joinStyle: path.joinStyle
property int joinStyle: ShapePath.BevelJoin //workaround for regression in Qt 6.6.1 (QDS-11845)
/*!
\include CommonItemDescriptions.qdocinc component-capStyle
*/
//property alias capStyle: path.capStyle
property int capStyle: ShapePath.FlatCap //workaround for regression in Qt 6.6.1 (QDS-11845)
/*!
\include CommonItemDescriptions.qdocinc {component-strokeStyle} {pie}
*/
//property alias strokeStyle: path.strokeStyle
property int strokeStyle: ShapePath.SolidLine //workaround for regression in Qt 6.6.1 (QDS-11845)
/*!
\include CommonItemDescriptions.qdocinc {component-strokeWidth} {pie}
*/
property alias strokeWidth: path.strokeWidth
/*!
\include CommonItemDescriptions.qdocinc {component-strokeColor} {pie}
*/
property alias strokeColor: path.strokeColor
/*!
\include CommonItemDescriptions.qdocinc {component-dashPattern} {pie}
*/
property alias dashPattern: path.dashPattern
/*!
\include CommonItemDescriptions.qdocinc {component-fillColor} {pie}
If \l hideLine is \c false, a pie slice is drawn using the values of the \l begin and \l end
properties and filled with this color.
If \l hideLine is \c true, just the pie stroke is drawn and the area between the \l begin and
\l end points is filled.
*/
property alias fillColor: path.fillColor
/*!
\include CommonItemDescriptions.qdocinc {component-dashOffset} {pie}
*/
property alias dashOffset: path.dashOffset
/*!
The position in degrees where the pie begins.
The default value is 0.
To create a circle, set the value of this property to 0 and the value of the \l end property to
360.
*/
property real begin: 0
/*!
The position in degrees where the pie ends.
The default value is 90.
To create a circle, set the value of this property to 360 and the value of the \l begin property
to 0.
*/
property real end: 90
/*!
The area between \l begin and \l end.
*/
property real alpha: root.clamp(root.end - root.begin, 0, 359.9)
property bool __preferredRendererTypeAvailable: root.preferredRendererType !== undefined
property bool __curveRendererActive: root.__preferredRendererTypeAvailable
&& root.rendererType === Shape.CurveRenderer
layer.enabled: root.antialiasing && !root.__curveRendererActive
layer.smooth: root.antialiasing && !root.__curveRendererActive
layer.samples: root.antialiasing && !root.__curveRendererActive ? 4 : 0
function clamp(num, min, max) {
return Math.max(min, Math.min(num, max))
}
/*!
Whether to draw a pie slice or just the pie stroke (similar to an \l ArcItem).
*/
property bool hideLine: {
if (root.alpha <= 0)
return true
if (root.alpha >= 359)
return true
return false
}
function toRadians(degrees) {
return degrees * (Math.PI / 180.0)
}
function polarToCartesianX(centerX, centerY, radius, angleInDegrees) {
return centerX + radius * Math.cos(root.toRadians(angleInDegrees))
}
function polarToCartesianY(centerX, centerY, radius, angleInDegrees) {
return centerY + radius * Math.sin(root.toRadians(angleInDegrees))
}
ShapePath {
id: path
property real __xRadius: root.width / 2 - root.strokeWidth / 2
property real __yRadius: root.height / 2 - root.strokeWidth / 2
property real __xCenter: root.width / 2
property real __yCenter: root.height / 2
strokeColor: "red"
capStyle: root.capStyle
strokeStyle: root.strokeStyle
joinStyle: root.joinStyle
strokeWidth: 4
startX: root.hideLine ? root.polarToCartesianX(path.__xCenter, path.__yCenter, path.__xRadius, root.begin - 90)
: path.__xCenter
startY: root.hideLine ? root.polarToCartesianY(path.__xCenter, path.__yCenter, path.__yRadius, root.begin - 90)
: path.__yCenter
PathLine {
x: root.polarToCartesianX(path.__xCenter, path.__yCenter, path.__xRadius, root.begin - 90)
y: root.polarToCartesianY(path.__xCenter, path.__yCenter, path.__yRadius, root.begin - 90)
}
PathArc {
id: arc
x: root.polarToCartesianX(path.__xCenter, path.__yCenter, path.__xRadius, root.begin + root.alpha - 90)
y: root.polarToCartesianY(path.__xCenter, path.__yCenter, path.__yRadius, root.begin + root.alpha - 90)
radiusY: path.__yRadius;
radiusX: path.__xRadius;
useLargeArc: root.alpha > 180
}
PathLine {
x: root.hideLine ? root.polarToCartesianX(path.__xCenter, path.__yCenter, path.__xRadius, root.begin + root.alpha - 90)
: path.__xCenter
y: root.hideLine ? root.polarToCartesianY(path.__xCenter, path.__yCenter, path.__yRadius, root.begin + root.alpha - 90)
: path.__yCenter
}
}
Component.onCompleted: {
// If preferredRendererType wasn't set initially make CurveRenderer the default
if (root.__preferredRendererTypeAvailable && root.preferredRendererType === Shape.UnknownRenderer)
root.preferredRendererType = Shape.CurveRenderer
}
}
|
