src/imports/designeffects/shaders/gaussianBlur.frag


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

#version 440
layout(location = 0) in vec2 qt_TexCoord0;
layout(location = 0) out vec4 fragColor;
layout(std140, binding = 0) uniform buf {
    mat4 qt_Matrix;
    float qt_Opacity;

    float blurKernel;
    float sigma;
    vec2 pixelSize;
    int useOffscreenColor; // bool
    vec4 offscreenColor;
};
layout(binding = 1) uniform sampler2D src;

const float PI = 3.14159265359;
const float sqrtDoublePI = sqrt(2.0 * PI);

vec4 gaussianBlur(sampler2D tex, int miplevel) {
    vec4 col = vec4(0.0);

    float sum = 0;

    float k = ceil(blurKernel);

    // Normalize kernel weights
    for (float i = -k; i <= k; ++i) {
        sum += exp(-0.5 * pow(i / sigma, 2.0)) / (sqrtDoublePI * sigma);
    }

    for (float i = -k; i <= k; ++i) {
        vec2 coord = qt_TexCoord0 + (pixelSize * float(i));
        float weight = exp(-0.5 * pow(i / sigma, 2.0)) / (sqrtDoublePI * sigma);

        if (useOffscreenColor != 0
            && (coord.x > 1.0 || coord.y > 1.0
                || coord.x < 0.0 || coord.y < 0.0)) {
            col += offscreenColor * weight / sum;
        } else {
            col += texture(tex, coord) * weight / sum;
        }
    }

    return col;
}

void main() {
    vec4 p = (blurKernel > 0) ? gaussianBlur(src, 0)
                              : texture(src, qt_TexCoord0);

    fragColor = p * qt_Opacity;
}