blob: a429d34b0c68cd5534ea981457666a2e11dc850b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
TEMPLATE = lib
CONFIG += dll
win32 {
# Uncomment the following line to build a plugin that can be used also in
# Internet Explorer, through ActiveX.
# CONFIG += qaxserver
} else {
CONFIG += plugin
}
INCLUDEPATH += $$PWD
DEPENDPATH += $$PWD
SOURCES += $$PWD/qtbrowserplugin.cpp
HEADERS += $$PWD/qtbrowserplugin.h qtnpapi.h
win32 {
SOURCES += $$PWD/qtbrowserplugin_win.cpp
!isEmpty(TARGET) {
TARGET = np$$TARGET
}
LIBS += -luser32
qaxserver {
DEF_FILE += $$PWD/qtbrowserpluginax.def
} else {
DEF_FILE += $$PWD/qtbrowserplugin.def
}
firefox {
exists("c:/program files/mozilla firefox/plugins") {
DLLDESTDIR += "c:/program files/mozilla firefox/plugins"
} else {
message("Firefox not found at default location")
}
}
opera {
exists("c:/program files/opera/program/plugins") {
DLLDESTDIR += "c:/program files/opera/program/plugins"
} else {
message("Opera not found at default location")
}
}
netscape {
exists("c:/program files/netscape/netscape browser/plugins") {
DLLDESTDIR += "c:/program files/netscape/netscape browser/plugins"
} else {
message("Netscape not found at default location")
}
}
} else:mac {
CONFIG += plugin_bundle
SOURCES += $$PWD/qtbrowserplugin_mac.cpp
#target.path = /Library/Internet\ Plugins
#INSTALLS += target
} else {
SOURCES += $$PWD/qtbrowserplugin_x11.cpp
INCLUDEPATH += /usr/X11R6/include
# Avoiding symbol clash with other instances of the Qt library
# (ref. developingplugins.html in the doc.):
#
# For Qt 4.4 and later, just configure Qt to use a separate namespace:
# configure -qtnamespace SomeNamespace
#
# For Qt 4.3: Uncomment the line below.
# It makes the dynamic linker prefer our own Qt symbols for the plugin,
# provided that our Qt is statically built and linked into the
# plugin. Note that to force the linker to prefer the static Qt
# libraries (.a files), the dynamic libraries (.so) files must not
# be present in the lib directory.
#
# QMAKE_LFLAGS += -Wl,-Bsymbolic
}
|
