blob: 2521c830696dd8619c0037083a4f779024cc83c9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
|
// Copyright (C) 2019 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
import QtQuick
import QtQuick3D
Window {
id: window
width: 640
height: 640
visible: true
color: "black"
Item {
id: qt_logo
width: 230
height: 230
anchors.top: parent.top
anchors.left: parent.left
anchors.margins: 10
//! [offscreenSurface]
layer.enabled: true
//! [offscreenSurface]
Rectangle {
anchors.fill: parent
color: "black"
//! [2d]
Image {
anchors.fill: parent
source: "qt_logo.png"
}
Text {
anchors.bottom: parent.bottom
anchors.left: parent.left
color: "white"
font.pixelSize: 17
text: qsTr("The Future is Written with Qt")
}
//! [2d]
//! [2danimation]
transform: Rotation {
id: rotation
origin.x: qt_logo.width / 2
origin.y: qt_logo.height / 2
axis { x: 1; y: 0; z: 0 }
}
PropertyAnimation {
id: flip1
target: rotation
property: "angle"
duration: 600
to: 180
from: 0
}
PropertyAnimation {
id: flip2
target: rotation
property: "angle"
duration: 600
to: 360
from: 180
}
//! [2danimation]
}
}
View3D {
id: view
anchors.fill: parent
PerspectiveCamera {
position: Qt.vector3d(0, 200, 300)
eulerRotation.x: -30
}
DirectionalLight {
eulerRotation.x: -30
}
Model {
//! [3dcube]
id: cube
source: "#Cube"
materials: PrincipledMaterial {
baseColorMap: Texture {
sourceItem: qt_logo
}
}
eulerRotation.y: 90
//! [3dcube]
Vector3dAnimation on eulerRotation {
loops: Animation.Infinite
duration: 5000
from: Qt.vector3d(0, 0, 0)
to: Qt.vector3d(360, 0, 360)
}
}
}
MouseArea {
id: mouseArea
anchors.fill: qt_logo
Text {
id: clickme
anchors.top: mouseArea.top
anchors.horizontalCenter: mouseArea.horizontalCenter
font.pixelSize: 17
text: "Click me!"
SequentialAnimation on color {
loops: Animation.Infinite
ColorAnimation { duration: 400; from: "white"; to: "black" }
ColorAnimation { duration: 400; from: "black"; to: "white" }
}
states: [
State {
name: "flipped";
AnchorChanges {
target: clickme
anchors.top: undefined
// QTBUG-101364
anchors.bottom: mouseArea.bottom // qmllint disable incompatible-type
}
}
]
}
onClicked: {
// do nothing while animating
if (flip1.running || flip2.running)
return;
if (clickme.state === "flipped") {
clickme.state = "";
flip2.start();
} else {
clickme.state = "flipped";
flip1.start();
}
}
}
}
|
