examples/quick3d/orderindependenttransparency/Instancing.qml


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203

// Copyright (C) 2024 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause

import QtQuick
import QtQuick.Controls
import QtQuick3D
import QtQuick3D.Helpers

Item {
    id: mainWindow
    anchors.fill: parent

    View3D {
        id: view3D
        anchors.fill: parent
        camera: camera

        environment: SceneEnvironment {
            clearColor: "#000000"
            antialiasingMode: AppSettings.antialiasingMode
            antialiasingQuality: AppSettings.antialiasingQuality
            backgroundMode: SceneEnvironment.SkyBox
            lightProbe: Texture {
                textureData: ProceduralSkyTextureData{}
            }
            oitMethod: SceneEnvironment.OITWeightedBlended
        }

        Node {
            PerspectiveCamera {
                id: camera
                position: Qt.vector3d(0, 100, 300)
            }


        }

        Node {
            id: sceneRoot

            Model {
                id: pillar
                source: "#Cylinder"
                scale: Qt.vector3d(0.3, 100, 0.3)
                position: Qt.vector3d(100, 0, 100)
                materials: [
                    PrincipledMaterial {
                        id: pillarMaterial
                        normalMap: Texture {
                            source: "images/pillar_normal.png"
                            scaleU: 20.0
                        }
                        roughness: 0.2
                    }
                ]
            }

            Model {
                id: pillar2
                source: "#Cylinder"
                scale: Qt.vector3d(0.3, 100, 0.3)
                position: Qt.vector3d(-100, 0, 100)
                materials: [
                    PrincipledMaterial {
                        id: pillarMaterial2
                        normalMap: Texture {
                            source: "images/pillar_normal.png"
                            scaleU: 20.0
                        }

                        roughness: 0.2
                    }
                ]
            }

            RandomInstancing {
                id: randomInstancing
                instanceCount: 80

                position: InstanceRange {
                    from: Qt.vector3d(-200, -200, -200)
                    to: Qt.vector3d(200, 200, 200)
                }
                scale: InstanceRange {
                    from: Qt.vector3d(5, 5, 5)
                    to: Qt.vector3d(20, 20, 20)
                    proportional: true
                }
                rotation: InstanceRange {
                    from: Qt.vector3d(0, 0, 0)
                    to: Qt.vector3d(360, 360, 360)
                }
                color: InstanceRange {
                    from: "grey"
                    to: "white"
                    proportional: true
                }

                randomSeed: 1423
            }
            DirectionalLight {
                position: Qt.vector3d(0, -300, 0)
                eulerRotation: Qt.vector3d(-90, 0, 0)
                brightness: 4
                color: Qt.rgba(0.8, 0.8, 1.0, 1.0)
            }

            Node {
                NumberAnimation on eulerRotation.y {
                    duration: 30000
                    from: 0
                    to: 360
                    loops: Animation.Infinite
                    running: true
                }
                PointLight {
                    id: pointLight
                    position: Qt.vector3d(0, 100, 300)
                    brightness: 1
                    ambientColor: Qt.rgba(0.5, 0.3, 0.1, 1.0)
                    SequentialAnimation {
                        loops: Animation.Infinite
                        running: true
                        NumberAnimation {
                            target: pointLight
                            property: "brightness"
                            to: 1
                            duration: 2000
                            easing.type: Easing.OutElastic
                        }
                        NumberAnimation {
                            target: pointLight
                            property: "brightness"
                            to: 2
                            duration: 6000
                            easing.type: Easing.InOutQuad
                        }
                    }
                }
                PointLight {
                    id: pointLight2
                    position: Qt.vector3d(100, 100, 300)
                    brightness: 1
                    ambientColor: Qt.rgba(0.5, 0.3, 0.1, 1.0)
                    SequentialAnimation {
                        loops: Animation.Infinite
                        running: true
                        NumberAnimation {
                            target: pointLight
                            property: "brightness"
                            to: 1
                            duration: 2000
                            easing.type: Easing.OutElastic
                        }
                        NumberAnimation {
                            target: pointLight
                            property: "brightness"
                            to: 2
                            duration: 6000
                            easing.type: Easing.InOutQuad
                        }
                    }
                }
                Model {
                    instancing: randomInstancing
                    source: "meshes/asteroid.mesh"
                    opacity: 0.5

                    materials: [
                        PrincipledMaterial {
                            baseColor: "#c0e0cc"
                            roughness: 0.1
                            cullMode: Material.NoCulling
                        }
                    ]
                }
            }

        }
    }

    Pane {
        anchors.top: view3D.top
        anchors.right: parent.right
        Label {
            id: debugViewToggleText
            text: dbg.visible ? "Hide DebugView" : "Show DebugView"
            anchors.right: parent.right
            anchors.top: parent.top
            MouseArea {
                anchors.fill: parent
                onClicked: dbg.visible = !dbg.visible
                DebugView {
                    y: debugViewToggleText.height * 2
                    anchors.right: parent.right
                    source: view3D
                    id: dbg
                    visible: false
                }
            }
        }
    }
}