examples/scxml/trafficlight-qml-simple/MainView.qml


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

// Copyright (C) 2023 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause

import QtQuick
import TrafficLightApplication

Window {
    id: root
    visible: true
    width: 100
    height: 350

    TrafficLightStateMachine {
        id: stateMachine
        running: true
    }

    Item {
        id: lights
        width: parent.width
        height: 300

        Light {
            anchors.top: parent.top
            anchors.horizontalCenter: parent.horizontalCenter
            color: "red"
            visible: stateMachine.red || stateMachine.redGoingGreen
        }

        Light {
            anchors.centerIn: parent
            color: "yellow"
            visible: stateMachine.yellow || stateMachine.blinking
        }

        Light {
            anchors.bottom: parent.bottom
            anchors.horizontalCenter: parent.horizontalCenter
            color: "green"
            visible: stateMachine.green
        }
    }

    Rectangle {
        anchors.top: lights.bottom
        anchors.bottom: parent.bottom
        width: parent.width
        border.color: "black"

        Text {
            anchors.fill: parent
            text: stateMachine.working ? "Pause" : "Unpause"
            horizontalAlignment: Text.AlignHCenter
            verticalAlignment: Text.AlignVCenter
        }

        MouseArea {
            anchors.fill: parent
            onClicked: stateMachine.submitEvent(stateMachine.working ? "smash" : "repair");
        }
    }
}