examples/sidebar.qml


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204

// Copyright (C) 2021 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause

import QtQuick
import QtQuick.Controls
import Qt.labs.UmlQuick.Generators

Rectangle {
    id: root
    width: 640
    height: 480
    color: rootHover.hovered ? "#555" : "#444"

    ObjectInstances {
        id: oi
        outputPrefix: "sidebarObjects-"
//        outputFormat: ObjectInstances.Graphviz
        nodeColorSource: ObjectInstances.ItemColor
        root: root
    }
    Component.onCompleted: oi.generate()

    component FlashAnimation: SequentialAnimation {
        id: tapFlash
        running: false
        loops: 3
        PropertyAction { value: false }
        PauseAnimation { duration: 100 }
        PropertyAction { value: true }
        PauseAnimation { duration: 100 }
    }

    component ButtonsAndStuff: Column {
        anchors.fill: parent
        anchors.margins: 8
        spacing: 8

        CheckBox {
            id: hoverBlockingCB
            text: "Button hover is blocking"
        }

        Rectangle {
            objectName: "buttonWithMA"
            width: parent.width
            height: 30
            color: buttonMA.pressed ? "lightsteelblue" : "#999"
            border.color: buttonMA.containsMouse ? "cyan" : "transparent"

            MouseArea {
                id: buttonMA
                objectName: "buttonMA"
                hoverEnabled: true
                cursorShape: Qt.UpArrowCursor
                anchors.fill: parent
                onClicked: console.log("clicked MA")
            }

            Text {
                anchors.centerIn: parent
                text: "MouseArea"
            }
        }

        Rectangle {
            objectName: "buttonWithHH"
            width: parent.width
            height: 30
            color: flash ? "#999" : "white"
            border.color: buttonHH.hovered ? "cyan" : "transparent"
            property bool flash: true

            HoverHandler {
                id: buttonHH
                objectName: "buttonHH"
                acceptedDevices: PointerDevice.AllDevices
                blocking: hoverBlockingCB.checked
                cursorShape: tapHandler.pressed ? Qt.BusyCursor : Qt.PointingHandCursor
            }

            TapHandler {
                id: tapHandler
                onTapped: tapFlash.start()
            }

            Text {
                anchors.centerIn: parent
                text: "HoverHandler"
            }

            FlashAnimation on flash {
                id: tapFlash
            }
        }
    }

    Rectangle {
        id: paddle
        width: 100
        height: 40
        color: paddleHH.hovered ? "indianred" : "#888"
        y: parent.height - 100
        radius: 10

        HoverHandler {
            id: paddleHH
            objectName: "paddleHH"
        }

        SequentialAnimation on x {
            NumberAnimation {
                to: root.width - paddle.width
                duration: 2000
                easing { type: Easing.InOutQuad }
            }
            PauseAnimation { duration: 100 }
            NumberAnimation {
                to: 0
                duration: 2000
                easing { type: Easing.InOutQuad }
            }
            PauseAnimation { duration: 100 }
            loops: Animation.Infinite
        }
    }

    Rectangle {
        objectName: "topSidebar"
        radius: 5
        antialiasing: true
        x: -10
        y: -radius
        width: 200
        height: 200
        border.color: topSidebarHH.hovered ? "cyan" : "black"
        color: "#777"

        Rectangle {
            color: "cyan"
            width: 10
            height: width
            radius: width / 2
            visible: topSidebarHH.hovered
            x: topSidebarHH.point.position.x - width / 2
            y: topSidebarHH.point.position.y - height / 2
            z: 100
        }

        HoverHandler {
            id: topSidebarHH
            objectName: "topSidebarHH"
            cursorShape: Qt.OpenHandCursor
        }

        ButtonsAndStuff {
            anchors.fill: parent
        }

        Text {
            anchors { left: parent.left; bottom: parent.bottom; margins: 12 }
            text: "Hover Handler"
        }
    }

    Rectangle {
        objectName: "bottomSidebar"
        radius: 5
        antialiasing: true
        x: -10
        anchors.bottom: parent.bottom
        anchors.bottomMargin: -radius
        width: 200
        height: 200
        border.color: bottomSidebarMA.containsMouse ? "cyan" : "black"
        color: "#777"

        MouseArea {
            id: bottomSidebarMA
            objectName: "bottomSidebarMA"
            hoverEnabled: true
            cursorShape: Qt.ClosedHandCursor
            anchors.fill: parent

            ButtonsAndStuff {
                anchors.fill: parent
            }
        }

        Text {
            anchors { left: parent.left; bottom: parent.bottom; margins: 12 }
            text: "MouseArea"
        }
    }

    HoverHandler {
        id: rootHover
    }

    Text {
        anchors.right: parent.right
        color: "cyan"
        text: "scene " + rootHover.point.scenePosition.x.toFixed(1) + ", " + rootHover.point.scenePosition.y.toFixed(1)
    }
}